Использование static enum
Внимание: Данная статья предназначена для "продвинутых" пользователей.
Статья содержит много теории и изобилует костылями, а потому не рекомендуется к прочтению обычным скриптерам.
Я вас предупредил.
|
Как некоторые из вас могли заметить, год назад в компиляторе от Zeex'а версии 3.10.2 появилась возможность объявлять статические перечисления (#136, #141).
static enum eMyInfo
{
miField1,
miField2
};
Отличие статических перечислений от обычных в том, что их область видимости ограничена только файлом, в котором они объявлены (как переменными или функциями, тоже объявленными с классификатором static). Такие перечисления идеально подходят для написания инклудов, когда нужно объявить перечисление, предназначенное для использования только внутри инклуда.
Но что, если при использовании этой фичи нужно сохранить совместимость со старыми версиями компилятора, в которых фичи static enum нет?
Следует сначала убедиться, что компилятор поддерживает эту фичу, если нет - использовать просто enum, без static.
Для начала разберёмся, как различить разные версии компилятора. Допустим, у нас компилятор версии "3.10.2". Мажорная и минорная составляющие "3" и "10" будут закодированы в константе __Pawn (0x3A), номер билда "2" - в __PawnBuild.
Константа __PawnBuild появилась всего год назад в версии 3.10.1, до этого номер билда никак не обозначался, во всех версиях в __Pawn было записано значение 0x3A и не было возможности различать разные билды (собственно, для решения этой проблемы и добавили константу __PawnBuild).
При использовании __PawnBuild нужно сначала убедиться в том, что константа объявлена (это делается с помощью оператора defined), иначе компилятор выдаст ошибку "undefined symbol".
Попробуем объявить макрос static_enum, который будет раскрываться в "static enum" для версий, на которых поддерживаются статические перечисления, и в "enum" для остальных версий.
Вы наверняка подумаете, что это очень просто:
#if defined __PawnBuild && __PawnBuild >= 2
#define static_enum static enum
#else
// Если более старая версия компилятора - откатываемся до обычного enum.
#define static_enum enum
#endif
Но не тут-то было! При попытке собрать это стандартным компилятором от SA:MP Team получаем:
Цитата:
error 017: undefined symbol "__PawnBuild"
Ошибка козникает на строке
#if defined __PawnBuild && __PawnBuild >= 2
Поскольку оператор defined не "выплёвывает" ошибку, а возвращает 0, если его операнд не объявлен, ошибка явно выдаётся на второй части выражения, после знака "&&".
Но как такое возможно? Мы же с помощью defined проверили, объявлена ли константа __PawnBuild - если не объявлена, то подвыражение после "&&" не должно выполняться, ведь уже заранее известно, что результатом всего выражения будет ложь (0).
... или должно?
Оказывается, в директивах компилятор обрабатывает выражения "ленивым" методом, т.е. даже когда одно из подвыражений делает заведомо ложным всё выражение (как в случае выше с __PawnBuild), он всё равно вычисляет оставшиеся подвыражения.
Тогда как же поступить с объявлением макроса static_enum? Легко, используем две директивы #if: в одной проверим существование константы __PawnBuild, а в другой - её значение.
#if defined __PawnBuild
#if __PawnBuild >= 2 // Компилятор не станет обрабатывать эту строку, если константа
// __PawnBuild не объявлена, следовательно, не будет и ошибки.
#define static_enum static enum
#endif
#endif
#if !defined static_enum
// Если макрос static_enum не был объявлен выше - мы имеем дело
// со старой версией компилятора; откатываемся до обычного enum.
#define static_enum enum
#endif
Остаётся только один изъян: мажорная и минорная версии компилятора не проверяются, учитывается только номер билда.
Если в будущем версия компилятора увеличится (например, константа __Pawn будет равна не 0x3A, а 0x3B, что будет соответствовать версии "3.11" вместо нынешней "3.10"), макрос static_enum на будущих версиях 3.11.0 и 3.11.1 будет раскрываться в "enum", как на старых версиях.
Учтём эту возможность:
#if __Pawn >= 0x3A && defined __PawnBuild
#if __Pawn > 0x3A || __PawnBuild >= 2
#define static_enum static enum
#endif
#endif
#if !defined static_enum
#define static_enum enum
#endif
И после этого можно смело использовать static_enum в своих инклудах:
static_enum my_inc_ExampleInfo // префикс "my_inc_" лучше оставить на случай, если используется
{ // старый компилятор, чтобы избежать коллизии имён
eiField1,
eiField2
};
БонусНебольшой бонус для тех, кто дочитал статью: с помощью всё тех же статических перечислений можно решить ещё одну проблему.
Если использовать
static const для ограничении зоны видимости константы внутри инклуда, после компиляции константа будет вести себя, как переменная: при каждом обращении к ней будет тратиться лишнее время на то, чтобы считать её значение из секции данных.
Но со
static enum тоже можно объявлять константы, которые технически будут именно константами, подставленными на места обращения во время компиляции, а не переменными со статусом read-only. Пусть оператор
enum и не предназначен для объявления одиночных констант, но это всяко лучше, чем отсутствие альтернативы.
#if __Pawn >= 0x3A && defined __PawnBuild
#if __Pawn > 0x3A || __PawnBuild >= 2
#define static_const(%0) static enum { %0 }
#endif
#endif
#if !defined static_const
#define static_const(%0) static const %0
#endif
Пример использования:
static_const(MY_CONST = 0);
Автор статьи: Daniel_Cortez
Благодарности:- VVWVV - реализация static enum.
Специально для
Pro-Pawn.ru
Копирование данной статьи на других ресурсах без разрешения автора запрещено!
