Вид для печати
Привет.
Видел на одном сервере такую фишку, вводишь в чат: Text [id:playerid] text а в чат выводится так: {FFFFFF}Text {FFFF00}NickName {FFFFFF}продолжение текста
Немножко погуглил
И наткнулся на тот же вариант
Затем мне не понравился этот "BBCode" и я решил сделать так: @id23 //типо как на вк :)
Начал переделывать SearchCode, но в конечном итоге компилятор отказался компилироваться. HELP!
- - - Добавлено - - -
@id23:
@id - код для поиска
23 - playerid
OKStyle что-то подобное делал, в беседе в ВК проскакивал код, потом пороюсь и найду :)
Версия OKStyle не работает в некоторых случаях.
Это вообще реально сделать?Цитата:
Сообщение от Londlem
Нашел
PHP код:public OnPlayerText(playerid, text[])
{
new PlayerName[MAX_PLAYER_NAME];
for(new i = strfind(text, "@", true), a = 0, tmp[4]; i != -1; i = strfind(text, "@", true, i)) // нашли включение обращения
{
++i, a = 0; // если их несколько - продолжаем до конца
while(48 <= text[i] <= 57 && a != 4) tmp[a++] = text[i++]; // ы
if(tmp[0] == EOS) continue; // если не найден
GetPlayerName(strval(tmp), PlayerName, sizeof(PlayerName)); // получаем имя введённого в чат ID
strdel(text, i - a - 1, i); // удаляем символ и ID
strins(text, PlayerName, i - a - 1, 128); // вставляем ник в чат
}
GetPlayerName(playerid, PlayerName, sizeof(PlayerName));
format(text, 128, "%s: {FFFFF}%s", PlayerName, text);
SendClientMessageToAll(GetPlayerColor(playerid), text);
return 0;
}
Этот код изменяет ту же строку, что и получает на входе, при этом в функцию strins в качестве длины строки всё время передаётся 128, из-за чего не мудрено словить выход за пределы массива. Мало того, этот выход будет не в коде на Pawn, а в нативной функции, что может привести к крашу или другим непредсказуемым результатам. Легендарный код такой легендарный.Цитата:
Сообщение от Untonyst
Точно помню, что делал что-то подобное раньше, попробую поискать в своих заготовках.
UPD: Пример кода, на котором фейлится функция от OKStyle:
PHP код:#include <a_samp>
my_GetPlayerName(playerid, output[], size)
{
static const names[][MAX_PLAYER_NAME] =
{
{"Nick1"},
{"Nick2"},
{"Nick_Abcdefgh"}
};
if((playerid < 0) || (playerid >= sizeof(names)))
return 0;
output[0] = '\0';
return strcat(output, names[playerid], size);
}
#if defined _ALS_GetPlayerName
#undef GetPlayerName
#else
#define _ALS_GetPlayerName
#endif
#define GetPlayerName my_GetPlayerName
public OnPlayerText(playerid, text[])
{
new PlayerName[MAX_PLAYER_NAME];
for(new i = strfind(text, "@", true), a = 0, tmp[4]; i != -1; i = strfind(text, "@", true, i))
{
++i, a = 0;
while(48 <= text[i] <= 57 && a != 4) tmp[a++] = text[i++];
if(tmp[0] == EOS) continue;
GetPlayerName(strval(tmp), PlayerName, sizeof(PlayerName));
strdel(text, i - a - 1, i);
strins(text, PlayerName, i - a - 1, 128);
}
GetPlayerName(playerid, PlayerName, sizeof(PlayerName));
format(text, 128, "%s: {FFFFF}%s", PlayerName, text);
SendClientMessageToAll(GetPlayerColor(playerid), text);
return 0;
}
main()
{
static test_string[] = "Wassup, @0! @2? @3?";
OnPlayerText(0, test_string);
print(test_string);
}
Пример использования:PHP код:ParseReferences(const text[], output[], size = sizeof(output))
{ // by Daniel_Cortez \\pro-pawn.ru
static size_m_1, nickname_pos1, nickname_pos2, ref_playerid, pos1, pos2, c;
size_m_1 = size - 1;
pos1 = 0, pos2 = strlen(output);
for(;;)
{
if(text[pos1] == '@')
{
nickname_pos1 = pos1, nickname_pos2 = pos2;
ref_playerid = 0;
while((c = text[++pos1]), '0' <= c <= '9')
ref_playerid = ref_playerid * 10 + (c - '0');
pos2 += GetPlayerName(
ref_playerid,
output[nickname_pos2],
size - nickname_pos2
);
if(pos2 == nickname_pos2)
output[pos2++] = '@', pos1 = nickname_pos1 + 1;
}
else if((output[pos2++] = text[pos1++]) == '\0')
break;
if(pos2 == size_m_1)
{
output[pos2] = '\0';
break;
}
}
}
P.S.: С вариантом от OKStyle сравнивать нет смысла из-за неправильной работы последнего. С другими вариантами (при предоставлении оных в этой теме) могу сравнить, как по валидности работы алгоритма, так и по производительности, но уже не сегодня.PHP код:public OnPlayerText(playerid, text[])
{
new parsed_text[144+1];
GetPlayerName(playerid, parsed_text, sizeof(parsed_text));
strcat(parsed_text, " сказал: ");
ParseReferences(text, parsed_text);
SendClientMessageToAll(-1, parsed_text);
return 0;
}
Цитата:
Сообщение от Daniel_Cortez
Если не трудно можешь пример использования через format сделать а то я не понел
Эмм
PHP код:public OnPlayerText(playerid, text[])
{
new parsed_text[144+1], player_name[MAX_PLAYER_NAME+1];
GetPlayerName(playerid, player_name, sizeof(player_name));
ParseReferences(text, parsed_text);
format(parsed_text, sizeof(parsed_text), "%s сказал: %s", player_name, parsed_text);
SendClientMessageToAll(-1, parsed_text);
return 0;
}
Обнаруженные баги:Цитата:
Сообщение от DeimoS
Если написать больше 20-и раз @playerid, то OnPlayerText возвращает 1, и каким-то чудо способом игнорится SendClientMessageToAll (см. цитирование).
Пожелания:
1) Хотелось бы перед узнаваемым ником, определялся цвет ника игрока. Кто может помочь с этим вопросом, стучитесь в ЛС. 50 рубликов могу дать.)
2) Если написать @playerid больше 2-х раз, то пишем игроку "Максимум 2 ника!");
Если верить вашему описанию, то это, скорее всего, выход за пределы массива. Интересно.Цитата:
Сообщение от Иван Бубнов
Какую строку вводите в чате? И какой никнейм соответствует вводимому(-ым) ID?
Могу сделать, как только разберусь с проблемой выше.Цитата:
Сообщение от Иван Бубнов
Нет абсолютно никакой необходимости добавлять это в мою функцию, вы и сами можете можете проверить строку на вхождение символа "@".Цитата:
Сообщение от Иван Бубнов
PHP код:for (new pos = -1, special_char_count = 0; text[++pos] != 0;)
if ((special_char_count += _:(text[pos] == '@')) > 2)
return SendClientMessage(playerid, -1, "Ошибка: Разрешено указывать до 2 никнеймов.");
Просто написал 23 раза @0 (0 ид игрока). Никнейм игрока ид 0:Цитата:
Сообщение от Daniel_Cortez
haew970f
Не получилось воспроизвести ошибку, на моём тестовом сервере никаких выходов за пределы массива нет.Цитата:
Сообщение от Иван Бубнов
Я даже сделал контрольные буферы до и после обрабатываемой строки, инициализировал их нулями и проверял неизменность значений в них после выполнения ParseReferences (crashdetect не всегда может самостоятельно определить выход за пределы массива в нативных строковых функциях, поэтому приходится так костылить), всё чисто.
Тем не менее, я только что исправил баг, из-за которого при неправильно введённых ID (например "@playerid" вместо "@1") брался никнейм игрока с ID 0.
PHP код:ParseReferences(const text[], output[], size = sizeof(output))
{ // by Daniel_Cortez \\pro-pawn.ru
static size_m_1, nickname_pos1, nickname_pos2, ref_id, pos1, pos2, c;
size_m_1 = size - 1;
pos1 = 0, pos2 = strlen(output);
for(;;)
{
if(text[pos1] == '@')
{
nickname_pos1 = pos1, nickname_pos2 = pos2;
ref_id = 0;
while('0' <= (c = text[++pos1]) <= '9')
ref_id = ref_id * 10 + (c - '0');
if ((pos1 == nickname_pos1+1) || (0 == IsPlayerConnected(ref_id)))
output[pos2++] = '@', pos1 = nickname_pos1 + 1;
else
pos2 += GetPlayerName(
ref_id,
output[nickname_pos2],
size - nickname_pos2
);
}
else if((output[pos2++] = text[pos1++]) == '\0')
break;
if(pos2 == size_m_1)
{
output[pos2] = '\0';
break;
}
}
}
Дело все так-и оказался не в функции. Сейчас попытаюсь сделать так, чтобы перед определяемым ником ставился цвет ника, поделюсь)
Ок, только что воспроизвёл проблему и исправил её.
Дубль 3...
PHP код:ParseReferences(const text[], output[], size = sizeof(output))
{ // by Daniel_Cortez \\pro-pawn.ru
static size_m_1, nickname_pos1, nickname_pos2, ref_id, pos1, pos2, c;
size_m_1 = size - 1;
pos1 = 0, pos2 = strlen(output);
for (;;)
{
if (pos2 >= size_m_1)
{
if (pos2 == size_m_1)
output[pos2] = '\0';
break;
}
if (text[pos1] == '@')
{
nickname_pos1 = pos1, nickname_pos2 = pos2;
ref_id = 0;
while('0' <= (c = text[++pos1]) <= '9')
ref_id = ref_id * 10 + (c - '0');
if ((pos1 == nickname_pos1+1) || (0 == IsPlayerConnected(ref_id)))
{
output[pos2++] = '@', pos1 = nickname_pos1 + 1;
continue;
}
pos2 += GetPlayerName(
ref_id,
output[nickname_pos2],
size - nickname_pos2
);
}
else if ((output[pos2++] = text[pos1++]) == '\0')
break;
}
}
Не смог.Цитата:
Сообщение от Иван Бубнов
Close!