Оповещание

Простите за такой слегка глупый вопрос, но как создать оповещание администрации для античита, к примеру у меня имеется античит на спид - хак - он кикает, мне требуется чтобы администрации после кика игрока ( Читера ) писало это, то что тот игрок кикнут за использование спид - хака, писало чтобы чисто администрации

Делаешь цикл на всех игроков, через switch или if делаешь проверку на переменную в которой хранится уровень админа, и выводишь им.

Ну дак continue + цикл + обычное оповещение.

PHP код:

---

 forward SendAdminMessage(color, string[]);
public SendAdminMessage(color, string[])
{
    foreach(new i: Player)
    {
        if(!PlayerInfo[i][pAdmin]) continue;
        SendClientMessage(i, color, string);
    }
} 


---

Цитата:

---

Сообщение от Bublik_Public

Ну дак continue + цикл + обычное оповещение.

---

Интересный у вас цикл по вашим словам, сначала пропуск итерации, а потом уже цикл. :mosking:


Первая версия ( компилятор сам высчитывает длину строки, то есть не нужно считать, сколько нужно выделять памяти на сообщение ):

PHP код:

---

static const
    fmt_str[] = "Игрок %s был кикнут по подозрению на Speed Hack."; // Само сообщение в массиве

new
    str[sizeof(fmt_str) - 2 + MAX_PLAYER_NAME],
    // сначала указываем массив со строкой, далее вычитаем два,
    // т.к. "%s" занимаем 2 символа в строки,
    // и прибавляем значение константы MAX_PLAYER_NAME ( макс. длина никнейма игрока )
    i = GetMaxPlayers();
    // получаем макс. количество игроков,
    // которое может играть на сервере ( для перебора игроков, и отбирание тех, которые являются админами )
    
GetPlayerName(playerid, str, sizeof(str)); // Получение никнейма, и сразу же запись в массив str, мы его ещё не использовали

format(str, sizeof(str), fmt_str, str); // Форматируем сообщение для верного отображения в чате.

do // цикл do while, самый лучший на мой взгляд цикл для перебора игроков
{
    --i; // Вычтем из переменной единицы ( теперь значение переменной i будет равно i - 1, то есть, условие цикла будет выполняться, пока i положительное число ( см. ниже: while(i) )
    if(IsPlayerConnected(i) && IsPlayerAdmin(i)) // если текущий игрок в итераторе подключен и если он является админом
        SendClientMessage(i, -1, str); // выведем игроку сообщение, которое содержится в массиве fmt_str ( исходная строка: str )
}
while(i); 


---

Вторая версия, для начинающего более простая, на мой взгляд, ( может и не так ):

PHP код:

---

new
    str[67],
    i = GetMaxPlayers();

GetPlayerName(playerid, str, sizeof(str));

format(str, 67, "Игрок %s был кикнут по подозрению на Speed Hack.", str);

do
{
    --i;
    if(IsPlayerConnected(i) && IsPlayerAdmin(i))
        SendClientMessage(i, -1, str);
}
while(i); 


---

SendAdminMessage, мне кажется это более легкий способ?

PHP код:

---

        new Float:veh_health_now,Float: veh_speed = GetPlayerSpeed ( playerid );
        GetVehicleHealth( player_vehicle[ playerid ],veh_health_now );
        if( veh_speed - speed_player [ playerid ] > 20 && veh_health_now - vehicle_health [ playerid ] == 0 )
        {
            Kick( playerid );/
            return 1;
        }
        speed_player [ playerid ] = veh_speed; 


---

Куда именно вставлять то что мне требуется, дабы было оповещение о том какого игрока кикнуло за чит, а оповестило администрацию

Цитата:

---

Сообщение от Rick

SendAdminMessage, мне кажется это более легкий способ?

---

Это вам всего лишь предоставили функцию, которая отправляет сообщение админам сервера, которое вы укажете во втором параметре.
Также она будет работать только у тех, кто использует инклюд foreach. И на сколько я помню вам нужно построить само сообщение, а не только функцию. Вот примерно так это всё должно выглядеть:

PHP код:

---

new
    Float: veh_health_now,
    Float: veh_speed = GetPlayerSpeed(playerid);

GetVehicleHealth(player_vehicle[playerid], veh_health_now);

if(veh_speed - speed_player[playerid] > 20 && veh_health_now - vehicle_health[playerid] == 0)
{
    new
        str[67],
        i = GetMaxPlayers();

    GetPlayerName(playerid, str, sizeof(str));

    format(str, 67, "Игрок %s был кикнут по подозрению на Speed Hack.", str);

    do
    {
        --i;
        if(IsPlayerConnected(i) && IsPlayerAdmin(i))
            SendClientMessage(i, -1, str);
    }
    while(i);

    Kick(playerid);

    return 1;
}
speed_player[playerid] = veh_speed; 


---

- - - Добавлено - - -

Также могу посоветовать функцию, чтобы каждый раз не писать повторяющийся код:

PHP код:

---

stock SendToAdminsCheaterText(const playerid, const is_kick = 1, const text[])
{
    new
        str[80],
        i = GetMaxPlayers();

    GetPlayerName(playerid, str, sizeof(str));

    format(str, 80, "Игрок %s был %s по подозрению на %s.", str, is_kick ? ("кикнут") : ("забанен"), text);

    do
    {
        --i;
        if(IsPlayerConnected(i) && IsPlayerAdmin(i))
            SendClientMessage(i, -1, str);
    }
    while(i);
} 


---

Использование такое:

PHP код:

---

SendToAdminsCheaterText(playerid, 1, "Speed Hack"); 


---

Выведет в чат ( допустим ):

Код:

---

Игрок Londlem был кикнут по подозрению на Speed Hack.

---

Второй аргумент ( который в примере принимает значение 1 ) даёт понять, что игрок кикнут, если поставить 0, будет вместо слова 'кикнут' заменено на 'забанен'.

Для вашего примера можно сделать так:

PHP код:

---

if(veh_speed - speed_player[playerid] > 20 && veh_health_now - vehicle_health[playerid] == 0)
{
    SendToAdminsCheaterText(playerid, 1, "Speed Hack");

    Kick(playerid);

    return 1;
} 


---

Проблема решена, спасибо всем кто отозвался. Особенно Londlem