Команда ID

[Skyline]

Здравствуйте, подскажите, как сделать команду ID чтобы при вводе первых например букв ника, выдавало все возможное варианты Ну например играет на сервере игрок с ником который начинается на A, вводишь /id A и выдает все ники которые на A начинаются, ну и по ID так же)
Буду очень признателен.

[wAx]

http://pro-pawn.ru/archive/index.php/t-10842.html посмотри тут

[Nexius_Tailer]

Если конкретно для ников, то юзай strfind для поиска введённой части по никам игроков

[Skyline]

Если конкретно для ников, то юзай strfind для поиска введённой части по никам игроков

Ну нужно чтобы и ник можно было бы ввести и ID

[Nexius_Tailer]

Ну нужно чтобы и ник можно было бы ввести и ID

Тогда sscanf пробуй

[DeimoS]

Список ников выводить так (не тестировал):

CMD:test(playerid, params[])
{
    new buff_player_name[MAX_PLAYER_NAME],
        len = strlen(params);
    
    if(!(1 <= len < MAX_PLAYER_NAME))
        return SendClientMessage(playerid, -1, "Слишком коротко/длинно");

    for(new i; i < MAX_PLAYERS; i++)
    {
        if(!IsPlayerConnected(i)) 
            continue;
        GetPlayerName(i, buff_player_name, MAX_PLAYER_NAME);
        if(strcmp(buff_player_name, params, len))
            continue;
        SendClientMessage(playerid, -1, buff_player_name);
    }
    return 1;
}  

Чтоб добавить возможность указывать ID, добавляй в самое начало проверку на то, хранится ли в params число и если хранится, обрабатывай как ID. Иначе - ник.

Ну или просто погугли получше и найди готовую команду. Я такое ещё в далёком 2012-ом видел в каком-то из ДМ модов

[Nexius_Tailer]

А вообще совсем забыл, у меня по описанному принципу реализован в одном проекте подобный поиск, правда только для объектов/транспорта и прочего, без sscanf'а. Вот пример (если введено неполное имя или много совпадений - выводит их список, если совпадение одно - делает действие).

    if(!(1 <= len < MAX_PLAYERS))
        return SendClientMessage(playerid, -1, "Слишком коротко/длинно");  

Наверное "MAX_PLAYER_NAME" имел в виду)

[ziggi]

Моя команда на основе sscanf с подсветкой найденной части ника.

CMD:id(playerid, params[])
{
    #if !defined COMMAND_ID_MAX_MATCHES
        #define COMMAND_ID_MAX_MATCHES 10
    #endif

    new
        ids[COMMAND_ID_MAX_MATCHES];

    if (sscanf(params, "?<MATCH_NAME_PARTIAL=1>u[" #COMMAND_ID_MAX_MATCHES "]", ids)) {
        SendClientMessage(playerid, -1, "{FFCC66}[Применение]: {FFFFFF}/id <часть ника>");
        return 1;
    }
    #undef COMMAND_ID_MAX_MATCHES

    new
        i,
        insert_pos,
        string[MAX_PLAYER_NAME + 18 + 3 + 3];

    while (ids[i] != INVALID_PLAYER_ID) {
        if (ids[i] == cellmin) {
            SendClientMessage(playerid, -1, "{FFCC66}* {FFFFFF}и другие...");
            break;
        }

        GetPlayerName(ids[i], string, sizeof(string));

        insert_pos = strfind(string, params, true);
        if (insert_pos != -1) {
            strins(string, "{FFFFFF}", strlen(params) + insert_pos);
            strins(string, "{FF8888}", insert_pos);
        }

        format(string, sizeof(string), "{FFCC66}* {FFFFFF}%s - %d", string, ids[i]);
        SendClientMessage(playerid, -1, string);

        ++i;
    }

    if (i == 0) {
        SendClientMessage(playerid, -1, "{FFCC66}* {FFFFFF}Никто не найден");
    }
    return 1;
}  

[Skyline]

А вообще совсем забыл, у меня по описанному принципу реализован в одном проекте подобный поиск, правда только для объектов/транспорта и прочего, без sscanf'а. Вот пример (если введено неполное имя или много совпадений - выводит их список, если совпадение одно - делает действие).

Извини не могу прогрузить страницу, если можно покажи часть кода для примера пожалуйста

- - - Добавлено - - -

Моя команда на основе sscanf с подсветкой найденной части ника.

CMD:id(playerid, params[])
{
    #if !defined COMMAND_ID_MAX_MATCHES
        #define COMMAND_ID_MAX_MATCHES 10
    #endif

    new
        ids[COMMAND_ID_MAX_MATCHES];

    if (sscanf(params, "?<MATCH_NAME_PARTIAL=1>u[" #COMMAND_ID_MAX_MATCHES "]", ids)) {
        SendClientMessage(playerid, -1, "{FFCC66}[Применение]: {FFFFFF}/id <часть ника>");
        return 1;
    }
    #undef COMMAND_ID_MAX_MATCHES

    new
        i,
        insert_pos,
        string[MAX_PLAYER_NAME + 16 + 4 + 3 + 1];

    while (ids[i] != INVALID_PLAYER_ID) {
        if (ids[i] == cellmin) {
            SendClientMessage(playerid, -1, "{FFCC66}* {FFFFFF}и другие...");
            break;
        }

        GetPlayerName(ids[i], string, sizeof(string));

        insert_pos = strfind(string, params, true);
        if (insert_pos != -1) {
            strins(string, "{FFFFFF}", strlen(params) + insert_pos);
            strins(string, "{FF8888}", insert_pos);
        }

        format(string, sizeof(string), "{FFCC66}* {FFFFFF}%s - %d", string, ids[i]);
        SendClientMessage(playerid, -1, string);

        ++i;
    }

    if (i == 0) {
        SendClientMessage(playerid, -1, "{FFCC66}* {FFFFFF}Никто не найден");
    }
    return 1;
}  

ziggi, почему то все появляются если даже ввожу часть ника к которой игрок не относится)
Задумка у тебя клевая

[ziggi]

Извини не могу прогрузить страницу, если можно покажи часть кода для примера пожалуйста

- - - Добавлено - - -



ziggi, почему то все появляются если даже ввожу часть ника к которой игрок не относится)
Задумка у тебя клевая

Странно, покажи что вводишь и что получаешь.