Продажа дома.

[Skyline]

Почему то при продаже дома, не изменяется ничего. Пикап остается, текст тоже и иконка, в БД все записывается норм.

if(strcmp(accept, "sh", true) == 0) 
    { 
        new house = pInfo[playerid][pHouse]; 
        strmid(HouseInfo[house][hOwner], "None", 0, strlen("None"), 255); 
        pInfo[playerid][pMoney] += HouseInfo[house][hPrice]; 
        GivePlayerMoney(playerid, HouseInfo[house][hPrice]); 
 
        HouseInfo[house][hOwned] = 0; 
        HouseInfo[house][hHouse_Car] = 410; 
        HouseInfo[house][hCar_Color_1] = 0; 
        HouseInfo[house][hCar_Color_2] = 0; 
        pInfo[playerid][pHouse] = 0; 
        DestroyVehicle(HouseCar[pInfo[playerid][pHouse]]); 
 
        Prodaga{playerid} = false; 
        SendClientMessage(playerid, COLOR_WHITE, !"Поздравляем с продажей дома."); 
         
 
        format(string, sizeof(string), "UPDATE `accounts` SET `house` = '%d' WHERE `id` = '%i'", pInfo[playerid][pHouse], pInfo[playerid][pID]); 
        mysql_tquery(mysql_connect_ID, string, "", ""); 
    }  

stock House3DText() 
{ 
    static const h_null[] = "{FFDEAD}ID: {FFFFFF}[%d]\n{FFDEAD}Владелец: {FFFFFF}Нет\n{FFDEAD}Стоимость: {FFFFFF}%d\n{FFDEAD}Уровень: {FFFFFF}%d"; 
     static const h_not_null[] = "{FFDEAD}ID: {FFFFFF}[%d]\n{FFDEAD}Владелец: {FFFFFF}%s\n{FFDEAD}Уровень: {FFFFFF}%d"; 
 
    new h_buff[sizeof(h_null) + ((3-2) + (24-2) + (20-2) + (5-2))]; 
    for(new h = 0; h <= TOTALHOUSE; h++) 
    { 
        if(!HouseInfo[h][hOwned]) 
        { 
            format(h_buff, sizeof(h_buff), h_null, HouseInfo[h][hID], HouseInfo[h][hPrice],HouseInfo[h][hLevel]); 
             HouseInfo[h][hPickup] = CreatePickup(1273, 1, HouseInfo[h][henter_pos_x], HouseInfo[h][henter_pos_y], HouseInfo[h][henter_pos_z], -1); 
             HouseInfo[h][hText]  = Create3DTextLabel(h_buff, 0x008080FF, HouseInfo[h][henter_pos_x], HouseInfo[h][henter_pos_y], HouseInfo[h][henter_pos_z], 7, 0); 
            HouseInfo[h][hMapicon] = CreateDynamicMapIcon(HouseInfo[h][henter_pos_x], HouseInfo[h][henter_pos_y], HouseInfo[h][henter_pos_z], 31, COLOR_WHITE, 0, -1, -1, 100.0); 
        } 
          else 
        { 
             DestroyDynamicMapIcon(HouseInfo[h][hMapicon]); 
            DestroyPickup(HouseInfo[h][hPickup]); 
            Delete3DTextLabel(HouseInfo[h][hText]); 
            format(h_buff, sizeof(h_buff), h_not_null, HouseInfo[h][hID], HouseInfo[h][hOwner],HouseInfo[h][hLevel]); 
            HouseInfo[h][hPickup] = CreatePickup(1272, 1, HouseInfo[h][henter_pos_x], HouseInfo[h][henter_pos_y], HouseInfo[h][henter_pos_z], -1); 
            HouseInfo[h][hText]  = Create3DTextLabel(h_buff, 0xFFFFFF, HouseInfo[h][henter_pos_x], HouseInfo[h][henter_pos_y], HouseInfo[h][henter_pos_z], 7.0, 0); 
        } 
    } 
}  

[Nash_Brigers]

House3DText вызвать забыл.

if(strcmp(accept, "sh", true) == 0) 
{ 
    new house = pInfo[playerid][pHouse]; 
    strmid(HouseInfo[house][hOwner], "None", 0, strlen("None"), 255); 
    pInfo[playerid][pMoney] += HouseInfo[house][hPrice]; 
    GivePlayerMoney(playerid, HouseInfo[house][hPrice]); 
 
    HouseInfo[house][hOwned] = 0; 
    HouseInfo[house][hHouse_Car] = 410; 
    HouseInfo[house][hCar_Color_1] = 0; 
    HouseInfo[house][hCar_Color_2] = 0; 
    pInfo[playerid][pHouse] = 0; 
    DestroyVehicle(HouseCar[pInfo[playerid][pHouse]]); 
 
    Prodaga{playerid} = false; 
    SendClientMessage(playerid, COLOR_WHITE, !"Ïîçäðàâëÿåì ñ ïðîäàæåé äîìà."); 
 
    format(string, sizeof(string), "UPDATE `accounts` SET `house` = '%d' WHERE `id` = '%i'", pInfo[playerid][pHouse], pInfo[playerid][pID]); 
    mysql_tquery(mysql_connect_ID, string, "", ""); 
     
    House3DText(); 
}  

[Skyline]

Да пробовал и так. Ничего не меняется все равно

[DeimoS]

Ну так а посмотреть на код, что есть, не вариант? Не видно, что в House3DText не удаляются старые маркеры/пикапы?
И лучше переименовать функцию хотя бы так:

  Открыть/закрыть

stock UpdateAllHouse() 
{ 
    static const h_null[] = "{FFDEAD}ID: {FFFFFF}[%d]\n{FFDEAD}Владелец: {FFFFFF}Нет\n{FFDEAD}Стоимость: {FFFFFF}%d\n{FFDEAD}Уровень: {FFFFFF}%d"; 
    static const h_not_null[] = "{FFDEAD}ID: {FFFFFF}[%d]\n{FFDEAD}Владелец: {FFFFFF}%s\n{FFDEAD}Уровень: {FFFFFF}%d"; 

    new h_buff[sizeof(h_null) + ((3-2) + (24-2) + (20-2) + (5-2))]; 
    for(new h = 0; h < sizeof(HouseInfo); h++) 
    { 
        DestroyDynamicMapIcon(HouseInfo[h][hMapicon]); 
        DestroyPickup(HouseInfo[h][hPickup]); 
        Delete3DTextLabel(HouseInfo[h][hText]); 
        if(!HouseInfo[h][hOwned]) 
        { 
            format(h_buff, sizeof(h_buff), h_null, HouseInfo[h][hID], HouseInfo[h][hPrice],HouseInfo[h][hLevel]); 
            HouseInfo[h][hPickup] = CreatePickup(1273, 1, HouseInfo[h][henter_pos_x], HouseInfo[h][henter_pos_y], HouseInfo[h][henter_pos_z], -1); 
            HouseInfo[h][hText]  = Create3DTextLabel(h_buff, 0x008080FF, HouseInfo[h][henter_pos_x], HouseInfo[h][henter_pos_y], HouseInfo[h][henter_pos_z], 7, 0); 
            HouseInfo[h][hMapicon] = CreateDynamicMapIcon(HouseInfo[h][henter_pos_x], HouseInfo[h][henter_pos_y], HouseInfo[h][henter_pos_z], 31, COLOR_WHITE, 0, -1, -1, 100.0); 
        } 
        else 
        { 
            format(h_buff, sizeof(h_buff), h_not_null, HouseInfo[h][hID], HouseInfo[h][hOwner],HouseInfo[h][hLevel]); 
            HouseInfo[h][hPickup] = CreatePickup(1272, 1, HouseInfo[h][henter_pos_x], HouseInfo[h][henter_pos_y], HouseInfo[h][henter_pos_z], -1); 
            HouseInfo[h][hText]  = Create3DTextLabel(h_buff, 0xFFFFFF, HouseInfo[h][henter_pos_x], HouseInfo[h][henter_pos_y], HouseInfo[h][henter_pos_z], 7.0, 0); 
            HouseInfo[h][hMapicon] = CreateDynamicMapIcon(HouseInfo[h][henter_pos_x], HouseInfo[h][henter_pos_y], HouseInfo[h][henter_pos_z], 32, COLOR_WHITE, 0, -1, -1, 100.0); 
        }
    }
    return 1;
}  

А для обновления конкретного дома создать аналог

  Открыть/закрыть

stock UpdateHouse(houseid) 
{ 
    if(!(0 <= houseid < sizeof(HouseInfo)))
        return 0;

    static const h_null[] = "{FFDEAD}ID: {FFFFFF}[%d]\n{FFDEAD}Владелец: {FFFFFF}Нет\n{FFDEAD}Стоимость: {FFFFFF}%d\n{FFDEAD}Уровень: {FFFFFF}%d"; 
    static const h_not_null[] = "{FFDEAD}ID: {FFFFFF}[%d]\n{FFDEAD}Владелец: {FFFFFF}%s\n{FFDEAD}Уровень: {FFFFFF}%d"; 

    new h_buff[sizeof(h_null) + ((3-2) + (24-2) + (20-2) + (5-2))]; 
    DestroyDynamicMapIcon(HouseInfo[houseid][hMapicon]); 
    DestroyPickup(HouseInfo[houseid][hPickup]); 
    Delete3DTextLabel(HouseInfo[houseid][hText]); 
    if(!HouseInfo[houseid][hOwned]) 
    { 
        format(h_buff, sizeof(h_buff), h_null, HouseInfo[houseid][hID], HouseInfo[houseid][hPrice],HouseInfo[houseid][hLevel]); 
        HouseInfo[houseid][hPickup] = CreatePickup(1273, 1, HouseInfo[houseid][henter_pos_x], HouseInfo[houseid][henter_pos_y], HouseInfo[houseid][henter_pos_z], -1); 
        HouseInfo[houseid][hText]  = Create3DTextLabel(h_buff, 0x008080FF, HouseInfo[houseid][henter_pos_x], HouseInfo[houseid][henter_pos_y], HouseInfo[houseid][henter_pos_z], 7, 0); 
        HouseInfo[houseid][hMapicon] = CreateDynamicMapIcon(HouseInfo[houseid][henter_pos_x], HouseInfo[houseid][henter_pos_y], HouseInfo[houseid][henter_pos_z], 31, COLOR_WHITE, 0, -1, -1, 100.0); 
    } 
    else 
    { 
        format(h_buff, sizeof(h_buff), h_not_null, HouseInfo[houseid][hID], HouseInfo[houseid][hOwner],HouseInfo[houseid][hLevel]); 
        HouseInfo[houseid][hPickup] = CreatePickup(1272, 1, HouseInfo[houseid][henter_pos_x], HouseInfo[houseid][henter_pos_y], HouseInfo[houseid][henter_pos_z], -1); 
        HouseInfo[houseid][hText]  = Create3DTextLabel(h_buff, 0xFFFFFF, HouseInfo[houseid][henter_pos_x], HouseInfo[houseid][henter_pos_y], HouseInfo[houseid][henter_pos_z], 7.0, 0); 
        HouseInfo[houseid][hMapicon] = CreateDynamicMapIcon(HouseInfo[houseid][henter_pos_x], HouseInfo[houseid][henter_pos_y], HouseInfo[houseid][henter_pos_z], 32, COLOR_WHITE, 0, -1, -1, 100.0); 
    }
    return 1;
}  

Дабы не обновлять все дома ради изменения состояния одного.
Собственно, твой код теперь будет таким

if(strcmp(accept, "sh", true) == 0) 
{ 
    new house = pInfo[playerid][pHouse]; 
    strmid(HouseInfo[house][hOwner], "None", 0, strlen("None"), 255); 
    pInfo[playerid][pMoney] += HouseInfo[house][hPrice]; 
    GivePlayerMoney(playerid, HouseInfo[house][hPrice]); 

    HouseInfo[house][hOwned] = 0; 
    HouseInfo[house][hHouse_Car] = 410; 
    HouseInfo[house][hCar_Color_1] = 0; 
    HouseInfo[house][hCar_Color_2] = 0; 
    pInfo[playerid][pHouse] = 0; 
    DestroyVehicle(HouseCar[pInfo[playerid][pHouse]]); 

    Prodaga{playerid} = false; 
    SendClientMessage(playerid, COLOR_WHITE, !"Поздравляем с продажей дома."); 


    format(string, sizeof(string), "UPDATE `accounts` SET `house` = '%d' WHERE `id` = '%i'", pInfo[playerid][pHouse], pInfo[playerid][pID]); 
    mysql_tquery(mysql_connect_ID, string, "", ""); 

    UpdateHouse(house);
}  

Ничего сверхестественного в том, что я сделал, нет. Просто нужно было разобрать код, что у тебя был и сам бы дошёл до этого. Не ленись в следующий раз :)

[Skyline]

Спасибо, но пикап и текст так же не изменяется(

[DeimoS]

Ну значит проверь, тот ли ID дома хранится в pHouse

[Skyline]

Ну значит проверь, тот ли ID дома хранится в pHouse

И снова спасибо) Прологировал все, действительно оказался ID не тот))