Как узнать из скольких символов состоит число?

[$continue$]

Так в данном случай мы тоже получим прирост производительности. Почему бы и нет?

А теперь бегом перечитывать все мои предыдущие сообщения, в которых я объяснял почему в данном случае эти миллисекунды важны.

[DeimoS]

Так в данном случай мы тоже получим прирост производительности. Почему бы и нет?

1) Код уже написан за тебя и тебе нужно лишь скопировать
2) Такая реализация не усложняет читаемость кода, но, при этом, повышает скорость.

С такой же логикой можно вообще забить на оптимизацию и писать как попало. А что, 2017 же!

UPD: перенёс вопрос в отдельную тему

[Daniel_Cortez]

>_>

<_<

Я просто оставлю это здесь:

stock GetNumberOfDigits(number)
{
    if (number < 100_000)
    {
        if (number < 100)
            return 1 + _:(number >= 10);
        if (number < 10_000)
            return 3 + _:(number >= 1_000);
        return 5;
    }
    if (number < 10_000_000)
        return 6 + _:(number >= 1_000_000);
    if (number < 1_000_000_000)
        return 8 + _:(number >= 100_000_000);
    return 10;
}  

  Открыть/закрыть

http://pro-pawn.ru/showthread.php?12585

/*======== Настройки =========================================================*/
#include <float>

const PROFILER_ITERATIONS_MAJOR = 100_000;
const PROFILER_ITERATIONS_MINOR = 10;

new const code_snippets_names[3][] =
{
    {"VVWVV"},
    {"DeimoS"},
    {"Daniel_Cortez"}
};

stock
    GetNumberOfDigits_VVWVV({Float,_}:number)
{
    return number != 0 ? floatround(floatlog(floatabs(number))) + 1 : 1;
}

stock GetCountsOfDigits_DeimoS(number)
{
    if(number < 100_000)
    {
        if(number < 100)
        {
            if(number < 10)
                return 1;
            else
                return 2;
        }
        else
        {
            if(number < 1_000)
                return 3;
            else
            {
                if(number < 10_000)
                    return 4;
                else
                    return 5;
            }
        }
    }
    else
    {
        if(number < 10_000_000)
        {
            if(number < 1_000_000)
                return 6;
            else
                return 7;
        }
        else
        {
            if(number < 100_000_000)
                return 8;
            else
            {
                if(number < 1_000_000_000)
                    return 9;
                else
                    return 10;
            }
        }
    }
}

stock GetNumberOfDigits_DC(number)
{
    if (number < 100_000)
    {
        if (number < 100)
            return 1 + _:(number >= 10);
        if (number < 10_000)
            return 3 + _:(number >= 1_000);
        return 5;
    }
    if (number < 10_000_000)
        return 6 + _:(number >= 1_000_000);
    if (number < 1_000_000_000)
        return 8 + _:(number >= 100_000_000);
    return 10;
}

// 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 20, ..., 90, 100, 200, ..., 2_000_000_000
static numbers[9 * 9 + 3];

#define Prerequisites();\
    numbers[0] = 0; \
    for (new i = 0, inc = 1, n = 1; i < 9; ++i, inc *= 10) \
        for (new j = 1; j < 10; ++j, n += inc) \
            numbers[i * 9 + j] = n; \
    numbers[82] = 1_000_000_000; \
    numbers[83] = 2_000_000_000; \
    static i;

#define CodeSnippet0();\
    for (i = 0; i < sizeof(numbers); ++i) \
        GetNumberOfDigits_VVWVV(numbers[i]);

#define CodeSnippet1();\
    for (i = 0; i < sizeof(numbers); ++i) \
        GetCountsOfDigits_DeimoS(numbers[i]);

#define CodeSnippet2();\
    for (i = 0; i < sizeof(numbers); ++i) \
        GetNumberOfDigits_DC(numbers[i]);
/*======== Конец настроек ===================================================*/  

Тестирование: 3 отрывка кода.
Режим: интерпретируемый, 100000x10 итераций.
VVWVV: 26177
DeimoS: 7585
Daniel_Cortez: 6924

Тестирование: 3 отрывка кода.
Режим: с JIT-компиляцией, 100000x10 итераций.
VVWVV: 9168
DeimoS: 1093
Daniel_Cortez: 1085

 DeimoS:

Ты шо, это ведь слишком сложно в написании и не компактно! Гораздо важнее сэкономить количество строк

[VVWVV]

>_>

<_<

Я просто оставлю это здесь:

stock GetNumberOfDigits(number)
{
    if (number < 100_000)
    {
        if (number < 100)
            return 1 + _:(number >= 10);
        if (number < 10_000)
            return 3 + _:(number >= 1_000);
        return 5;
    }
    if (number < 10_000_000)
        return 6 + _:(number >= 1_000_000);
    if (number < 1_000_000_000)
        return 8 + _:(number >= 100_000_000);
    return 10;
}  

Я, пожалуй, перенесу данную функцию в тему с GetNumberOfDigits (с указанием авторства), если ты не против..

[Daniel_Cortez]

Я, пожалуй, перенесу данную функцию в тему с GetNumberOfDigits (с указанием авторства), если ты не против..

Не против, только лучше обнови его ещё раз. В моём коде, равно как и в коде DeimoS'а, не учитывались отрицательные числа.
Исправленная версия:

stock GetNumberOfDigits(number)
{ // by Daniel_Cortez \\ pro-pawn.ru
    if (number < 0)
        number = -number;
    if (number < 100_000)
    {
        if (number < 100)
            return 1 + _:(number >= 10);
        if (number < 10_000)
            return 3 + _:(number >= 1_000);
        return 5;
    }
    if (number < 10_000_000)
        return 6 + _:(number >= 1_000_000);
    if (number < 1_000_000_000)
        return 8 + _:(number >= 100_000_000);
    return 10;
}  

Тест производительности (в вариант DeimoS'а я тоже добавил проверку на отрицательные числа):

  Открыть/закрыть

#include <float>

const PROFILER_ITERATIONS_MAJOR = 100_000;
const PROFILER_ITERATIONS_MINOR = 10;

new const code_snippets_names[3][] =
{
    {"VVWVV"},
    {"DeimoS"},
    {"Daniel_Cortez"}
};

stock
    GetNumberOfDigits_VVWVV({Float,_}:number)
{
    return number != 0 ? floatround(floatlog(floatabs(number))) + 1 : 1;
}

stock GetCountsOfDigits_DeimoS(number)
{
    if (number < 0)
        number = -number;
    if (number < 100_000)
    {
        if(number < 100)
        {
            if(number < 10)
                return 1;
            else
                return 2;
        }
        else
        {
            if(number < 1_000)
                return 3;
            else
            {
                if(number < 10_000)
                    return 4;
                else
                    return 5;
            }
        }
    }
    else
    {
        if(number < 10_000_000)
        {
            if(number < 1_000_000)
                return 6;
            else
                return 7;
        }
        else
        {
            if(number < 100_000_000)
                return 8;
            else
            {
                if(number < 1_000_000_000)
                    return 9;
                else
                    return 10;
            }
        }
    }
}

stock GetNumberOfDigits_DC(number)
{
    if (number < 0)
        number = -number;
    if (number < 100_000)
    {
        if (number < 100)
            return 1 + _:(number >= 10);
        if (number < 10_000)
            return 3 + _:(number >= 1_000);
        return 5;
    }
    if (number < 10_000_000)
        return 6 + _:(number >= 1_000_000);
    if (number < 1_000_000_000)
        return 8 + _:(number >= 100_000_000);
    return 10;
}

// 0, -1, 2, -3, 4, -5, 6, -7, 8, -9, 10, -20, ..., 90, -100, 200, ..., -2_000_000_000
static numbers[9 * 9 + 3];

#define Prerequisites(); \
    numbers[0] = 0; \
    for (new i = 0, inc = 1, n = 1; i < 9; ++i, inc *= 10) \
        for (new j = 1; j < 10; ++j, n += inc) \
            numbers[i * 9 + j] = n * (((i * 9 + j) & 1) * -2 + 1); \
    numbers[82] = 1_000_000_000; \
    numbers[83] = -2_000_000_000; \
    static i;

#define CodeSnippet0(); \
    for (i = 0; i < sizeof(numbers); ++i) \
        GetNumberOfDigits_VVWVV(numbers[i]);

#define CodeSnippet1(); \
    for (i = 0; i < sizeof(numbers); ++i) \
        GetCountsOfDigits_DeimoS(numbers[i]);

#define CodeSnippet2(); \
    for (i = 0; i < sizeof(numbers); ++i) \
        GetNumberOfDigits_DC(numbers[i]);  

Режим: интерпретируемый, 100000x10 итераций.
VVWVV: 26277
DeimoS: 10300
Daniel_Cortez: 9775

Режим: с JIT-компиляцией, 100000x10 итераций.
VVWVV: 9056
DeimoS: 1170
Daniel_Cortez: 1165

[NewGreen]

Что скажете насчет такого варианта:

stock GetCountsOfDigits(number)
{
    new counts = 0;
    if(number < 0)
        number = -number;
    while(number != 0) {
        counts++;
        number /= 10;
    }
    return counts;
}  

[$continue$]

Там была вверху ссылка на хабру. Вырезка из текста: "скорость которого линейно зависит от длины числа."

Что скажете насчет такого варианта:

stock GetCountsOfDigits(number)
{
    new counts = 0;
    if(number < 0)
        number = -number;
    while(number != 0) {
        counts++;
        number /= 10;
    }
    return counts;
}  

[NewGreen]

Там была вверху ссылка на хабру. Вырезка из текста: "скорость которого линейно зависит от длины числа."

Если не ошибаюсь то в pawn, ячейка равна 4 байта, следовательно максимальная длина проверяемого числа равна 10-ти - это немного.
Поэтому вряд ли этот вариант будет сильно уступать описанным выше.

[DeimoS]

Если не ошибаюсь то в pawn, ячейка равна 4 байта, следовательно максимальная длина проверяемого числа равна 10-ти - это немного.
Поэтому вряд ли этот вариант будет сильно уступать описанным выше.

А если всё же не гадать, а просто провести тесты?
Тем более, что выше уже практически готовый код есть.

Да и, опять же, с каких пор экономия строк стала выгоднее процессорного времени?

[NewGreen]

А если всё же не гадать, а просто провести тесты?
Тем более, что выше уже практически готовый код есть.
Да и, опять же, с каких пор экономия строк стала выгоднее процессорного времени?

Итераций 100000x100 (без jit) :
time_Deimos = -6975
time_DC = -6408
time_NewGreen = -18560

Итераций 100000x100 (с jit) :
time_Deimos = -457
time_DC = -522
time_NewGreen = -4460

В общем остальные вопросы "почему" отпадают)