Запрос в базу на проверку одинаковых значений

[Kucklovod00]

Доброго времени суток, уважаемая аудитория портала. При написании системы семьи, наткнулся на очень интересную вещь. В общем, мне нужно обнулить переменную у всех найденных аккаунтов в базе, которые совпадают с переменной определенного игрока.

Пример вызываемого СЕЛЕКТ-запроса:

CMD:kleave(playerid)
{
    mysql_query_string[0] = EOS;
    mysql_format(dbHandle, mysql_query_string, 128, "SELECT * FROM "T_ACCOUNTS" WHERE fam_m = %i LIMIT 1", pInfo[playerid][pFamilyMember]);
    mysql_tquery(dbHandle, mysql_query_string, "@CheckMemberFamily", "i", pInfo[playerid][pFamilyMember]);  
    return 1;
}  

Колбэк:

@CheckMemberFamily(famid);
@CheckMemberFamily(famid)
{
    new rows;
    cache_get_row_count(rows);
    if(rows)
    {
        mysql_query_string[0] = EOS;
        mysql_format(dbHandle, mysql_query_string, 70, "UPDATE "T_ACCOUNTS" SET fam_m = 0 WHERE fam_m = %i", famid);
        mysql_tquery(dbHandle, mysql_query_string, "", "");
    }
    foreach(new i : Player)
    {
        if(!gPlayerLogged[i]) continue;
        if(pInfo[i][pFamilyMember] != famid) continue;
        SendClientMessage(i, COLOR_RED, "Создатель вашей семьи покинул семью по собственному желанию");
        SendClientMessage(i, COLOR_RED, "Все участники были расформированы");
        pInfo[i][pFamilyMember] = 0;
    }
    mysql_query_string[0] = EOS;
    mysql_format(dbHandle, mysql_query_string, 50, "DELETE FROM "T_FAMILY" WHERE id = %i", famid);
    mysql_tquery(dbHandle, mysql_query_string, "", "");
    return 1;
}  

Правильно ли я все написал, и если нет, то как лучше?

[StevenH]

Зачем проверять значение fam_m в базе? Если в моде правильно настроена загрузка и сохранение, то оно по сути и не надо..

CMD:kleave(playerid)
{
    new query[90];
    foreach(new i : Player)
    {
        if(!gPlayerLogged[i]) continue;
        if(pInfo[i][pFamilyMember] != famid) continue;
        SendClientMessage(i, COLOR_RED, "Создатель вашей семьи покинул семью по собственному желанию");
        SendClientMessage(i, COLOR_RED, "Все участники были расформированы");
        pInfo[i][pFamilyMember] = 0;
    }
    mysql_format(dbHandle, query, sizeof(query), "UPDATE "T_ACCOUNTS" SET fam_m = 0 WHERE fam_m = %i", famid);
    mysql_tquery(dbHandle, query, "", "");
    mysql_format(dbHandle, query, sizeof(query), "DELETE FROM "T_FAMILY" WHERE id = %i", famid);
    mysql_tquery(dbHandle, query, "", "");
    return 1;
}  

[DeimoS]

Зачем ты сначала делаешь SELECT, если и так известно, состоит ли игрок в семье?
И зачем используешь mysql_format, если не экранируешь символы?
Так же итератор лучше создать отдельный для авторизированных игроков и отдельно для семей, а не лепить миллион проверок в итератор вех игроков.
И обнулять массив mysql_query_string нужно только если ты собираешься скреплять строки с его помощью, а-ля

for(new i; i < 10; i++)
{
    format(mysql_query_string, sizeof(mysql_query_string), "Привет!\n%s", mysql_query_string);
}  

Ибо в этом случае старое содержимое массива попадёт в форматирование. В случае, когда ты просто записываешь в массив новые данные, обнулять ничего не нужно, ибо функция сама всё перезапишет, так как ты указываешь запись с нулевой ячейки

Пробуй

CMD:kleave(playerid)
{
    new fam_id = pInfo[playerid][pFamilyMember];
    if(fam_id == INVALID_FAMILY_ID)// Сюда ещё нужно на ранг добавить проверку, иначе люой участник может написать команду и удалить семью
    {
        SendClientMessage(playerid, -1, "Вы не состоите в семье");
        return 1;
    }
    format(mysql_query_string, sizeof(mysql_query_string), "UPDATE "T_ACCOUNTS" SET fam_m = 0 WHERE fam_m = %d", fam_id);
    mysql_tquery(dbHandle, mysql_query_string, "", "");
    format(mysql_query_string, sizeof(mysql_query_string), "DELETE FROM "T_FAMILY" WHERE id = %i", fam_id);
    mysql_tquery(dbHandle, mysql_query_string, "", "");

    foreach(new i : Player)
    {
        if(!gPlayerLogged[i] || pInfo[i][pFamilyMember] != fam_id)
        {
            continue;
        }
        SendClientMessage(i, COLOR_RED, "Создатель вашей семьи покинул семью по собственному желанию");
        SendClientMessage(i, COLOR_RED, "Все участники были расформированы");
        pInfo[i][pFamilyMember] = 0;
    }
    return 1;
}  

[Kucklovod00]

Про mysql_format. Я слышал, что это для мускула только и нужно, мол защита от SQL инъекций и прочее. Проверки есть, просто убрал, что бы не засорять тему. Всем спасибо.

[DeimoS]

Ну так у mysql_format для этого есть специальный спецификатор - %e
Именно он экранирует спец-символы и его нужно использовать во всех случаях, когда игрок посылает какие-либо строковые данные в базу (вводить пароль/прописывает название семьи и т.п.).
В остальных случаях использовать данную функцию не стоит, ибо она медленнее нативки, так как сначала сервер отправляет данные плагину, потом тот обрабатывает и только потом результат получает сервер.

P.S. В 0.3.7 (вроде, R2) и в нативке появился спецификатор для экранирования спец-символов - %q. Так что, при желании, от mysql_format можно вообще отказаться.

[Kucklovod00]

Можно подробнее об обнулении массива?

[DeimoS]

Что именно не понятно-то?

[Kucklovod00]

В каких случаях нужно, а в каких нет. Речь не только о SQL запросах.

[DeimoS]

Эмм, ну функция format записывает текст относительно той ячейки, какую ты указал, а не относительно первого нуль-символа.
Когда ты прописываешь

format(string, sizeof(string), "Привет %s", pnayer_name);  

Эта запись равносильна

format(string[0], sizeof(string), "Привет %s", pnayer_name);  

То бишь, запись начнётся с нулевой ячейки независимо от того, есть ли в этих ячейках значение, отличное от нуля или нет (если вместо нуля указать, например, 5 - format начнёт записывать с пятой ячейки. Только тогда нужно учесть это во втором параметре, дабы выход за пределы массива не произошел при слишком длинном тексте). Соответственно, обнулять ничего не нужно, ибо format запишет текст и в конце поставит нуль-символ.

В данном случае обнулять нужно лишь тогда, когда тебе в коде нужно скрепить несколько строк, как я показывал в примере:

for(new i; i < 10; i++)
{
    format(string, sizeof(string), "%sСтрока №%d\n", string, i);// Тут мы вставляем старое содержимое массива string в нашу новую строку, за счёт чего скрепляем их
}  

Тут если не обнулить значение заранее, получится, что информация, которая уже была в массиве (с прошлого раза, например. Речь о глобальном массиве, если что) вставится в строку, чего нам не нужно, исходя из логики кода.


А вообще я советую тебе отказаться от глобального массива и перейти на локальные, дабы не усложнять код и предотвратить возможные ошибки из-за этого (например, можно начать писать код с использованием одного массива, а в коде, который уже будет выводить результат на экран, вставить не тот массив, с которым работал, а глобальный. В результате на экране появится совсем не то, что будет нужно, а код будет прекрасно компилироваться. И не факт, что сразу заметишь эту опечатку)

[Kucklovod00]

Ты как понимающий в этом, используешь в своих модах/отдельных систем (для опенсурс, например) глобальные массивы?