Превратить "1000000" в "1 000 000"

Цитата:

---

Сообщение от Josan_Solomon

Промелькнула шальная мысль хранить значение во float(а потом убирать точку), потом дошло что сам язык 32-х битный и ничего с этим ограничением уже не поделаешь. Как печально.. А как вы хранили бы большие числа?

- - - Добавлено - - -

И какое максимальное значение у float? Не нашел список диапазона значений для pawn

- - - Добавлено - - -

Поэкспериментировал и не нашел четкого ограничения, но увы, точность стала пропадать

---

Зачем вам такие числа? Если вы хотите хранить числа в диапазоне [0, 4294967296), то можно использовать библиотеку ulong. Тем не менее я не вижу абсолютно никакого смысла использовать в SA:MP значения больше имеющихся.

Цитата:

---

Сообщение от DeimoS

Есть ещё такой вариант

stock AddCommasToInt(number, delimiter[2] = ".")
{
    new int_string[10+3+1+1];
 
    format(int_string, sizeof(int_string), "%d", number >= 0 ? number : -number);//Если число положительное - запишем его в обычном виде. Иначе - добавим ещё один минус, дабы сделать его положительным
 
 
    new value = strlen(int_string);// Запишем в value размер строки с числом
 
    switch(value)
    {
        case 4..6: // Если переданное число содержит от 4-х до 6-и символов, добавим один разделитель
                    strins(int_string, delimiter, value-3,1);
        case 7..9: // Если от 7-и до 9-и - два разделителя
                    strins(int_string, delimiter, value-3,1),
                    strins(int_string, delimiter, value-6,1);
        case 10..12: // Если от 10-и до 12-и - три разделителя
                    strins(int_string, delimiter, value-3,1),
                    strins(int_string, delimiter, value-6,1),
                    strins(int_string, delimiter, value-9,1);
    }  
 
    if(number < 0) strins(int_string, "-", 0); // Если число отрицательное, вернём ему минус
    return int_string;
}

---

Немного поздно, но всё же: функция неправильно выводит cellmin, вместо "-2147483648" выводится "---" (причина кроется в баге в функции format()). Решение из formatnumber.inc тоже фейлит на cellmin.

Поделюсь своим костылём:

stock NumToString(dest[], num, sep = '\'', size = sizeof(dest))
{ // by Daniel_Cortez \\ pro-pawn.ru
    if (num == cellmin)
    {
        format(dest, size, "-2%c147%c483%c648", sep, sep, sep);
        return 14;
    }
    static neg, len, offs;
    new numstr[11];
    if ((neg = (num < 0)))
    {
        dest[0] = '-';
        size--;
        num = -num;
    }
    format(numstr, sizeof(numstr), "%d", num);
    offs = ((len = strlen(numstr)) - 1) % 3 + 1;
    switch (len)
    {
        case 1..3:
            return strunpack(dest[neg], numstr, size) + neg;
        case 4..6:
            return format(dest[neg], size, "%.*s%c%.3s", offs, numstr, sep, numstr[offs]), (len + neg + 1);
        case 7..9:
            return format(dest[neg], size, "%.*s%c%.3s%c%.3s", offs, numstr, sep, numstr[offs], sep, numstr[3+offs]), (len + neg + 2);
    }
    format(dest[neg], size, "%.*s%c%.3s%c%.3s%c%.3s", offs, numstr, sep, numstr[offs], sep, numstr[3+offs], sep, numstr[6+offs]);
    return len + neg + 3;
}

Из плюсов данного варианта: отсутствие возврата массива через стек (вместо этого пользователь сам должен указать массив для записи), правильный вывод cellmin, функция возвращает длину строки с числом.

Цитата:

---

Сообщение от Daniel_Cortez

...

---

Еще можно так это сделать.

stock
    ulong_string(dest[], ulong:value, bool:is_packed = false,
        delimiter, size = sizeof dest)
{
    dest[0] = '0';
    if (value) {
        if (is_packed)
            size <<= 2;
        new
            end = ulong_getDigitCount(value),
            mod = 0,
            part_size = 0,
            out_chr = 0;
        while (value) {
            // dest[end] = '0' + (value % 10)
            #emit load.s.pri value
            #emit const.alt 10
            #emit udiv
            #emit stor.s.pri value
            #emit stor.s.alt mod
 
            if (++part_size == 4) {
                part_size = 0;
                out_chr = delimiter;
            } else if (--end < size) {
                out_chr = '0' + mod;
            }
            if (is_packed) {
                dest{end} = out_chr;
            } else {
                dest[end] = out_chr;
            }
        }
    }
    return 0;
}