Как сделать переключение игроков при слежке?

Доброго времени суток.

На протяжении вечера не могу реализовать довольно легкую функцию "перелистывания" игрока в режиме наблюдения, через менюшку.

Тестирую с другом. Захожу за ним в наблюдение - все ок. Нажимаю NEXT и по логике должно остаться на этом же ID'e, ибо игрок с id 2 не онлайн, а получается либо выход за пределы массива, либо прочая фигня.

Тестировал разные варианты, но так и не нашел нормального способа. Заранее извиняюсь за нелогичный код, но голова не варит уже...

case 0: // next
{
    new 
            current_id, i;
 
    i = Iter_First(Player);
    while(i != Iter_End(Player)) {
 
        current_id = Iter_Next(Player, i);
 
        if(i == playerid || !IsPlayerLogin(i))
            continue;
 
        StartSpec(playerid, i);
 
        i = current_id;
 
        break;
    }
}

Либо так:

new
    current_id;
 
foreach(new i: Player) {
 
    current_id = Iter_Next(Player, i);
    if(current_id == playerid || !IsPlayerLogin(current_id))
        continue;
 
    StartSpec(playerid, current_id);
 
    break;
}

И многое другое... Ничего не хочет работать. Подскажите, пожалуйста, где ошибка.

Смотри:
При вызове Iter_Next, когда передаётся самое последнее доступное значение, функция возвращает значение Iter_End.
При вызове Iter_Prev, когда передаётся самое первое значение из доступных в итераторе, функция возвращает значение Iter_Begin (по сути, тот же Iter_End с тем же кодом, только название изменено, дабы было более говорящим для конкретной ситуации).

Соответственно, тебе нужно написать следующую логику:

1) Iter_Next
2) Iter_Next == Iter_End?
2.1) Если да, вызываем Iter_First (чтоб начать "новый круг")
2.1.1) Если функция Iter_First так же возвращает значение Iter_End, значит подходящих игроков больше нет
2.2) Если нет, то проверяем совпадение с playerid/другими следящими админами/прочей нужной инфой (в случае совпадения опять вызывать Iter_Next, только уже для значения, которое до этого вернула Iter_Next. Ну а если совпадений нет, то используем значение Iter_Next)

И в Iter_Next передавай не значение из foreach, а текущий ID игрока, за которым идёт слежка. Iter_Next/Iter_Prev созданы именно для определения следующего/предыдущего значения от текущего (указанного).


С Iter_Prev всё точно так же:
1) Iter_Prev
2) Iter_Prev == Iter_Begin?
2.1) Если да, вызываем Iter_Last (чтоб начать "новый круг")
2.1.1) Если функция Iter_Last так же возвращает значение Iter_Begin, значит подходящих игроков больше нет
2.2) Если нет, то проверяем совпадение с playerid/другими следящими админами/прочей нужной инфой (в случае совпадения опять вызывать Iter_Prev, только уже для значения, которое до этого вернула Iter_Prev. Ну а если совпадений нет, то используем значение Iter_Prev)

И точно так же никакого цикла foreach быть не должно. Внутри функций хранятся все нужные циклы и вычисления. Тебе нужно только сверять значения и использовать их.

Для проверок на совпадение с playerid и т.п. можно использовать goto, а не цикл (если, конечно, умеешь пользоваться). Код будет в разы компактнее и понятнее (ну с моей точки зрения).
goto тут лучше, ибо количество итераций, нужных для проверки, заранее неизвестно, и с циклом, скорее всего, придётся воротить дополнительные условия, раздувая код. А с goto у тебя будет тот же самый "голый" алгоритм + 2 строки с goto для зацикливания.

Спасибо за хорошее пояснения, но верно ли я понял?

case 0: // next
{
    new
        curr_next     =     Iter_Next(Player, GetSpecID(playerid)),
        curr_end     =    Iter_End(Player),
        next_id, i;
 
    if(curr_next) {
        if(curr_next == curr_end) {
 
            i = Iter_First(Player);
            if(i == curr_end) {
                return true;
            }
 
            else if(!pTemp[i][pLogined] || i == playerid) {
                next_id  = Iter_Next(Player, curr_next);
            } else {
                next_id = curr_next;
            }
        }
    }
    StartSpec(playerid, next_id);    
}

UPD: Кхм, не работает. Нажимаю на next, а он меня спавнит, хотя в паблик StartSpec передаются правильные значения.

Странноватый код. Если условие "curr_next == curr_end" не сработает, next_id останется с нулевым значением.

Как-то так:

case 0: // next
{
    new
        curr_next,
        curr_end = Iter_End(Player),
        start_id;
 
    start_id = curr_next = GetSpecID(playerid);
 
    __loop:
     curr_next = Iter_Next(Player, curr_next);
    if(curr_next == curr_end) 
    {
        curr_next = Iter_First(Player);
        if(curr_next == curr_end) 
        {
            // Тут нужна функция, которая завершает слежку
            return true;
        }
    }
 
    if(start_id != curr_next && (curr_next == playerid || !pTemp[curr_next][pLogined]))
    {
        goto __loop;
    }
    StartSpec(playerid, curr_next);    
}

Нужно проверить код на ситуациях, когда:
1) Есть только один залогиненный игрок, помимо тебя, а так же есть ещё один или несколько незалогиненных игроков (в этом случае должно вновь показать залогиненного игрока, а не уйти в бесконечный цикл)
2) Если на сервере только один игрок, помимо тебя.

Если всё сработает как надо, то код на обратную прокрутку будет точно таким же, только вместо Iter_Next будет Iter_Prev, а вместо Iter_First будет Iter_Last (Iter_End можно и не менять, ибо, как говорил, значение Iter_End и Iter_Begin выдают одинаковое)

Работает отлично, позже проверю остальное, но я думаю ситуация не изменится.

Большое спасибо!

Если будут проблемы - в личку отпиши и открою тему.