zcmd + sscanf (команды)

Доброе время суток еще раз.
В общем, можно ли как-то реализовать вот такой код:

PHP код:

---

public OnPlayerCommandText(playerid, cmdtext[])
{
    new cmd[128], idx;
    cmd = strtok(cmdtext, idx);
    if(strcmp(cmd, "/house", true) == 0)
    {
        cmd = strtok(cmdtext, idx);
        if(!strlen(cmd))
        {
            SendClientMessage(playerid, -1, "Используйте: /house [params]");
            SendClientMessage(playerid, -1, "sell - продать");
            SendClientMessage(playerid, -1, "enter - вход");
            SendClientMessage(playerid, -1, "exit - выход");
            return true;
        }
        if(strcmp(cmd, "sell", true) == 0)
        {
            cmd = strtok(cmdtext, idx);
            if(!strlen(cmd))
            {
                return SendClientMessage(playerid, -1, "Используйте: /house sell [amount]");
            }
            new amount = strval(tmp);
            //
            return true;
        }
        if(strcmp(cmd, "enter", true) == 0)
        {
            // вход
            return true;
        }
        if(strcmp(cmd, "exit", true) == 0)
        {
            // выход
            return true;
        }
        return true;
    }
    return true;
} 


---

на zcmd + sscanf, что бы параметры вводились постепенно, если можно пару примеров как это реализовать.

А к чему, собственно, подобный мазохизм?

Предлагаю варианты:

С использованием стандартного командного процессора + sscanf:

public OnPlayerCommandText(playerid, cmdtext[])
{
    static const house_cmd[] = "/house"; // имя команды с правым слэшем
    const house_cmd_size = sizeof(house_cmd)-1;
 
    if(strcmp(cmdtext, house_cmd, true, house_cmd_size) == 0)
    {
        new
            house_param_sell[] = "sell", // имя параметра "продажа"
            house_param_enter[] = "enter", // имя параметра "вход"
            house_param_exit[] = "exit"; // имя параметра "выход"
        const
            // подсчёт длин каждой команды во время компиляции
            house_param_sell_size = sizeof(house_param_sell)-1,
            house_param_enter_size = sizeof(house_param_enter)-1,
            house_param_exit_size = sizeof(house_param_exit)-1;
 
        // расчёт максимальной длины из указанных ранее параметров
        #if house_param_sell_size>house_param_enter_size
            #define final_size house_param_sell_size
        #else
            #define final_size house_param_enter_size
        #endif
        #if house_param_exit_size > final_size
            #undef final_size
            #define final_size house_param_exit_size+1
        #endif
 
        new
            param_name[final_size], // массив, содержащий имя параметра
            amount, // переменная, хранящая стоимость
            fmt_str[] = "s[%i]D(-1)", // массив спецификаторов
            spec_str[sizeof(fmt_str) + (-2 + 3)]; // массив, хранящий отформатированную строку со спецификаторами
 
        format(spec_str, sizeof(spec_str), fmt_str, final_size+1);
 
        #undef final_size
 
        sscanf(cmdtext[house_cmd_size], spec_str, param_name, amount);
        if(isnull(param_name)) // если не указан параметр
        {
            SendClientMessage(playerid, -1, "Используйте: /house [params]");
            SendClientMessage(playerid, -1, "sell - продать");
            SendClientMessage(playerid, -1, "enter - вход");
            SendClientMessage(playerid, -1, "exit - выход");
        }
        else if(strcmp(param_name, house_param_sell, true, house_param_sell_size) == 0)
        {
            if(amount == -1)
                return SendClientMessage(playerid, -1, "Используйте: /house sell [amount]");
        }
        else if(strcmp(param_name, house_param_enter, true, house_param_enter_size) == 0)
        {
            SendClientMessage(playerid, -1, "Вы вошли в ваш дом.");
        }
        else if(strcmp(param_name, house_param_exit, true, house_param_exit_size) == 0)
        {
            SendClientMessage(playerid, -1, "Вы вышли из вашего дома.");
        }
        else
        {
            print("Такой параметр не найден.");
        }
        return true;
    }
    return true;
}

Плюсы:

• Не нужно рассчитывать размер для строк и параметров;
• Все параметры хранятся в одном месте. Если нужно поменять имя параметра, то не нужно "далеко ходить";
• Размеры массивов вычисляются максимально точно

Минусы:

• Много кода;
• Небольшой минус к производительности (взамен автоматизации?);
• При добавлении нового параметра следует создавать константу для неё;

С использованием ZCMD + sscanf без всяких "изворотов":

CMD:house(playerid, params[])
{
    new
        param_str[6],
        amount;
    sscanf(params, "s[5]I(-1)", param_str, amount);
    if(isnull(param_str))
    {
        SendClientMessage(playerid, -1, "Используйте: /house [params]");
        SendClientMessage(playerid, -1, "sell - продать");
        SendClientMessage(playerid, -1, "enter - вход");
        SendClientMessage(playerid, -1, "exit - выход");
    }
    else if(strcmp(param_str, "sell", true) == 0)
    {
        if (amount <= 0)
            return SendClientMessage(playerid, -1, "Используйте: /house sell [amount]");
 
        // код для продажи дома
    }
    else if(strcmp(param_str, "enter", true) == 0)
    {
        SendClientMessage(playerid, -1, "Вы вошли в ваш дом.");
    }
    else if(strcmp(param_str, "exit", true) == 0)
    {
        SendClientMessage(playerid, -1, "Вы вышли из вашего дома.");
    }
    else
    {
        SendClientMessage(playerid, -1, "Указанный параметр не найден.");
    }
    return true;
}

P.S.: В сообщение будут вноситься правки при обнаружении более оптимизированных вариантов

Цитата:

---

Сообщение от L0ndl3m

Предлагаю вариант:
Плюсы:

• Не нужно рассчитывать размер для строк и параметров;
• Все параметры хранятся в одном месте. Если нужно поменять имя параметра, то не нужно "далеко ходить";
• Размеры массивов вычисляются максимально точно

Минусы:

• Много кода;
• Небольшой минус к производительности (взамен автоматизации?);
• При добавлении нового параметра следует создавать константу для неё;

P.S.: В сообщение будут вноситься правки при обнаружении более оптимизированных вариантов

---

Вот теперь ты точно вернулся)
p.s. Как обычно, какая-то фигня касаемо "ответить с цитированием" поэтому убрал код.
(почините уже это дерьмо, господи()

Цитата:

---

Сообщение от whale

А к чему, собственно, подобный мазохизм?

---

Очень удобно, в одной команде все подкоманды ненужно ничего запоминать.

- - - Добавлено - - -

Цитата:

---

Сообщение от L0ndl3m

Предлагаю варианты:

С использованием стандартного командного процессора + sscanf:

public OnPlayerCommandText(playerid, cmdtext[])
{
    static const house_cmd[] = "/house"; // имя команды с правым слэшем
    const house_cmd_size = sizeof(house_cmd)-1;
 
    if(strcmp(cmdtext, house_cmd, true, house_cmd_size) == 0)
    {
        new
            house_param_sell[] = "sell", // имя параметра "продажа"
            house_param_enter[] = "enter", // имя параметра "вход"
            house_param_exit[] = "exit"; // имя параметра "выход"
        const
            // подсчёт длин каждой команды во время компиляции
            house_param_sell_size = sizeof(house_param_sell)-1,
            house_param_enter_size = sizeof(house_param_enter)-1,
            house_param_exit_size = sizeof(house_param_exit)-1;
 
        // расчёт максимальной длины из указанных ранее параметров
        #if house_param_sell_size>house_param_enter_size
            #define final_size house_param_sell_size
        #else
            #define final_size house_param_enter_size
        #endif
        #if house_param_exit_size > final_size
            #undef final_size
            #define final_size house_param_exit_size+1
        #endif
 
        new
            param_name[final_size], // массив, содержащий имя параметра
            amount, // переменная, хранящая стоимость
            fmt_str[] = "s[%i]D(-1)", // массив спецификаторов
            spec_str[sizeof(fmt_str) + (-2 + 3)]; // массив, хранящий отформатированную строку со спецификаторами
 
        format(spec_str, sizeof(spec_str), fmt_str, final_size+1);
 
        #undef final_size
 
        sscanf(cmdtext[house_cmd_size], spec_str, param_name, amount);
        if(isnull(param_name)) // если не указан параметр
        {
            SendClientMessage(playerid, -1, "Используйте: /house [params]");
            SendClientMessage(playerid, -1, "sell - продать");
            SendClientMessage(playerid, -1, "enter - вход");
            SendClientMessage(playerid, -1, "exit - выход");
        }
        else if(strcmp(param_name, house_param_sell, true, house_param_sell_size) == 0)
        {
            if(amount == -1)
                return SendClientMessage(playerid, -1, "Используйте: /house sell [amount]");
        }
        else if(strcmp(param_name, house_param_enter, true, house_param_enter_size) == 0)
        {
            SendClientMessage(playerid, -1, "Вы вошли в ваш дом.");
        }
        else if(strcmp(param_name, house_param_exit, true, house_param_exit_size) == 0)
        {
            SendClientMessage(playerid, -1, "Вы вышли из вашего дома.");
        }
        else
        {
            print("Такой параметр не найден.");
        }
        return true;
    }
    return true;
}

Плюсы:

• Не нужно рассчитывать размер для строк и параметров;
• Все параметры хранятся в одном месте. Если нужно поменять имя параметра, то не нужно "далеко ходить";
• Размеры массивов вычисляются максимально точно

Минусы:

• Много кода;
• Небольшой минус к производительности (взамен автоматизации?);
• При добавлении нового параметра следует создавать константу для неё;

С использованием ZCMD + sscanf без всяких "изворотов":

CMD:house(playerid, params[])
{
    new
        param_str[6],
        amount;
    sscanf(params, "s[5]I(-1)", param_str, amount);
    if(isnull(param_str))
    {
        SendClientMessage(playerid, -1, "Используйте: /house [params]");
        SendClientMessage(playerid, -1, "sell - продать");
        SendClientMessage(playerid, -1, "enter - вход");
        SendClientMessage(playerid, -1, "exit - выход");
    }
    else if(strcmp(param_str, "sell", true) == 0)
    {
        if (amount <= 0)
            return SendClientMessage(playerid, -1, "Используйте: /house sell [amount]");
 
        // код для продажи дома
    }
    else if(strcmp(param_str, "enter", true) == 0)
    {
        SendClientMessage(playerid, -1, "Вы вошли в ваш дом.");
    }
    else if(strcmp(param_str, "exit", true) == 0)
    {
        SendClientMessage(playerid, -1, "Вы вышли из вашего дома.");
    }
    else
    {
        SendClientMessage(playerid, -1, "Указанный параметр не найден.");
    }
    return true;
}

P.S.: В сообщение будут вноситься правки при обнаружении более оптимизированных вариантов

---

Спасибо, попробую твой вариант.

Лучше уже y_stringhash воспользоваться

Цитата:

---

Сообщение от red.inc

Лучше уже y_stringhash воспользоваться

---

Особого профита от y_stringhash тут не будет. Код не так часто вызывается, чтоб важна была каждая миллисекунда.

---

  Открыть/закрыть

Предложу такой, ещё более автоматизированный, вариант:

enum _:e_HOUSECMD_ACTIONS_LIST
{
    HouseCMD_Action_Sell,
    HouseCMD_Action_Enter,
    HouseCMD_Action_Exit
};
new const housecmd_actions[e_HOUSECMD_ACTIONS_LIST][] =
{
    "sell",
    "enter",
    "exit"
};

SSCANF:housecmd_actions(const string[])
{
    for(new i; i < sizeof(housecmd_actions); i++)
    {
        if(strcmp(string, housecmd_actions[i], true))
            continue;
        return i;
    }
    return -1;
}

CMD:house(playerid, params[])
{
    new action;
    new amount;
    if(sscanf(params, "k<housecmd_actions>I(-1)", action, amount) || action == -1)
    {
        SendClientMessage(playerid, -1, "Используйте: /house [params]");
        SendClientMessage(playerid, -1, "sell - продать");
        SendClientMessage(playerid, -1, "enter - вход");
        SendClientMessage(playerid, -1, "exit - выход");
        return 1;
    }
    switch(action)
    {
        case HouseCMD_Action_Sell:
        {
            if (amount <= 0)
                return SendClientMessage(playerid, -1, "Используйте: /house sell [amount]");
 
            // код для продажи дома
        }
        case HouseCMD_Action_Enter:
        {
            SendClientMessage(playerid, -1, "Вы вошли в ваш дом.");
        }
        case HouseCMD_Action_Exit:
        {
            SendClientMessage(playerid, -1, "Вы вышли из вашего дома.");
        }
    }
    return true;
}

UPD: Хотя я не подумал, что, в случае изменения количества действий, всё равно придётся лезть в код команды для добавления нового элемента в switch, так что получится не так удобно, как задумывалось изначально. Думаю, второй вариант от L0ndl3m тут наиболее оптимальный.