Таблицы в бд

Я по твоему уроку создал регистрацию на mysql 39r,, всё отлично данные игрока и т.д всё норм, но вот я хочу теперь двинуться дальше и создать таблицу которая не касается самого игрока, а таблица где будет храниться разные штуки дрюки типа денег к примеру но он храниться будет в открытом доступе что бы любой игрок к примеру взять деньги из другой таблицы.

Типа казны но мне нужно лишь как её задействовать вот и всё можешь написать код что бы таблица грузилась при включении мода и там хранились данные? Буду благодарен!

Можно типа в stock создать мол хранилище и связать с таблицей типа на основе хранении данных игрока? или как это делается можешь объяснить *?

Ну так всё то же самое: создаёшь таблицу и создаёшь в ней нужный столбец. При запуске мода посылаешь запрос, как посылается в OnPlayerConnect и выгружаешь данные в переменную, с которой работаешь. При изменении значения посылаешь UPDATE запрос с новыми данными для переменной. Всё

Это типа через enum ?? переменные вписать? а там значение как устанавливается? типа числа которые будут хранится, можно чуть чуть поподробнее на примере? Очень буду признателен и благодарен

- - - Updated - - -

Если к примеру это таблица не будет связана с игроком тесно, там просто надо прописать загрузку в public OnGameModeInit()? и прописать сток для неё что бы был запрос об изменении? (сохранение ещё)

Я кое что насварганил, можешь подсказать правильно сделано или нет? Это чисто в самом моде будет, там типа храниться деньги и типа что бы игрок мог взять деньги . Я хочу узнать правильно ли указаны запросы и т.д и правильно ли подключаеться вообще таблица с включением мода, нужно ли выгружать данные типа и т.д

Это весь код который используется в моде именно для хранения денег:

В OnGameModeInit (что бы данные загружались при включении мода записано так.
Ко всем new добавлен:

PHP код:

---

new internet[1] 


---

PHP код:

---

public OnGameModeInit()
{
    mysql_connect_ID = mysql_connect(MYSQL_HOST, MYSQL_USER, MYSQL_DATABASE, MYSQL_PASSWORD);
    mysql_function_query(mysql_connect_ID, !"SET CHARACTER SET 'utf8'", false, "", "");
    mysql_function_query(mysql_connect_ID, !"SET NAMES 'utf8'", false, "", "");
    mysql_function_query(mysql_connect_ID, !"SET character_set_client = 'cp1251'", false, "", "");
    mysql_function_query(mysql_connect_ID, !"SET character_set_connection = 'cp1251'", false, "", "");
    mysql_function_query(mysql_connect_ID, !"SET character_set_results = 'cp1251'", false, "", "");
    mysql_function_query(mysql_connect_ID, !"SET SESSION collation_connection = 'utf8_general_ci'", false, "", "");
    mysql_tquery(mysql_connect_ID, "SELECT * FROM `internet`", "Uploadinternet", "");// ново 


---

Дальше идут стоки загрузки вроде( я сам не понимаю значение cache fiel это типа кэширование загруженного данного столба/таблицы? и сток с обновлением/сохранением.

PHP код:

---

stock Uploadinternet()
{
    internet[0] = cache_get_field_content_int(0, "iCash", mysql_connect_ID); //ново
}
stock Saveinternet()
{
    new query_string[26+3] = "UPDATE `internet` SET";

    format(query_string, sizeof(query_string), "%s `iCash` = '%d',", query_string, internet[0]);

    mysql_function_query(mysql_connect_ID, query_string, false, "", "");
    ResetPlayerMoney(playerid);
    GivePlayerMoney(playerid,s_player[playerid][pDollar]);
    return 1;
} 


---

Uploadinternet должен создаваться как public, а не как stock.
И зачем ты "internet" создал как массив?

Можешь на примере показать ? как это должно записываться в enum и как вообще сделать данные запросы, тот сток сделал как паблик.
У меня ещё вопрос, у меня в таблице стоит iCash и всё снизу нет ничего типа где должны быть циферки(бабки)

- - - Updated - - -

Дополняю, если к примеру я создаю общак и игроки типа смогут пользоваться то я должен добавлять MAX players типа
https://preview.ibb.co/cLnDV5/4324234.png
Можно по подробнее?

- - - Updated - - -

О я пересмотрел твой код там есть create account по его типу делать создание? типа insert и т.д?

- - - Updated - - -

Я думаю если я напишу создание этой ячейки то призагрузке мода он каждый раз будет создавать? или нет? если будет то как проверяь наличие этих данных и если они есть что бы не создавалась эти штуки (типа аккаунтов)

Погугли. Есть сотни статей, где объясняются элементарные вещи по работе с БД

В коннект? вставлять проверку на созданную таблицу ну по типу аккаута?

- - - Updated - - -

со всеми разобрался остался типа проверять мол есть ли уже созданая таблица что бы не создавалось поверх того что было создано ранее

Для чего вообще нужна эта переменная? Что за данные там хранятся?

Я её убрал и сделал enum vse нормально, но у меня теперь вопрос как создать эту штуку где храниться числа в таблице, ручным способом в самом mysql либо через запрос и куда этот запрос вставлять

Что убрал?
Я спрашиваю, какую информацию ты вообще хранить хочешь? Что это за деньги? Чьи они? Где будут использоваться?

как добавлять строки там уже в бд для хранение чисел?

- - - Updated - - -

Смотри, я создаю типа хранение денег в самом сервере, что бы любой игрок брал деньги именно из таблицы. Хочу сделать так что бы после взаимодействия будь то деньги, что угодно что бы из таблицы исчезало то количество которое было взято игроками. Вот типа пример такой

Деньги не чьи. Они просто будут храниться на сервере при загрузке мода сразу загружаться бд должен типа.. вот и всё

-_-
А деньги-то для каждого игрока индивидуальные или общее количество для всех?
Сформулируй нормально свою идею и напиши её сюда.

Общее, я хочу создать систему одну связано с хакерством и хаком банка. И типа хочу что бы при удачном хакерстве в данной штукенции списывались числа вот и всё в принципе. Но для этого же нужно типа создать где будет храниться информация в численном виде. Типа это таблица общая скажем так что бы ею пользоваться могли все игроки. Я дальше в системах проверки всякие сделаю и т.д Мне главное что бы правильно создать эти сохранения, загрузка самого таблицы и всё. И изменения .

- - - Updated - - -

щас кину свой корявый код :D которые не работает. Якобы создал :D

в ongamemode init

PHP код:

---

public OnGameModeInit()
{
    mysql_connect_ID = mysql_connect(MYSQL_HOST, MYSQL_USER, MYSQL_DATABASE, MYSQL_PASSWORD);
    mysql_function_query(mysql_connect_ID, !"SET CHARACTER SET 'utf8'", false, "", "");
    mysql_function_query(mysql_connect_ID, !"SET NAMES 'utf8'", false, "", "");
    mysql_function_query(mysql_connect_ID, !"SET character_set_client = 'cp1251'", false, "", "");
    mysql_function_query(mysql_connect_ID, !"SET character_set_connection = 'cp1251'", false, "", "");
    mysql_function_query(mysql_connect_ID, !"SET character_set_results = 'cp1251'", false, "", "");
    mysql_function_query(mysql_connect_ID, !"SET SESSION collation_connection = 'utf8_general_ci'", false, "", "");
    mysql_tquery(mysql_connect_ID, "SELECT * FROM `internet`", "Uploadinternet", "");// ново
    new query_string[35];
    format(query_string, sizeof(query_string), "SELECT * FROM `internet` WHERE `iCash` = '%d'", s_internet[iCash]);
     mysql_tquery(mysql_connect_ID, "Uploadinternet", "");
    createlistinternet(); 


---

сам enum

PHP код:

---

enum e_internet_go
{
    iCash
};
new s_internet[e_internet_go]; 


---

сток который ты сказал изменить на паблик

PHP код:

---

public Uploadinternet()
{
    s_internet[iCash] = cache_get_field_content_int(0, "iCash", mysql_connect_ID);
    return 1; //ново
} 


---

Сами вызываемые функции

PHP код:

---

stock Saveinternet()
{
    new query_string[26+3] = "UPDATE `internet` SET";

    format(query_string, sizeof(query_string), "%s `iCash` = '%d'", query_string, s_internet[iCash]);

    mysql_function_query(mysql_connect_ID, query_string, false, "", "");
    return 1;
}
stock createlistinternet()
{
    new query_string[30];
    format(query_string, sizeof(query_string), "INSERT INTO `internet` (`iCash`) VALUES ('%d')", s_internet[iCash]);
} 


---

Я очень буду благодарен если поможете мне реализовать Связь с бд.

И ты собрался создавать для этого таблицу с одним столбцом?
А когда нужно будет другую систему создать и так же хранить данные для неё, ты ещё одну таблицу создашь? :)

Создаёшь таблицу со структурой, типа:

PHP код:

---

id // AUTO_INCREMENT 0 Integer
data_name // Название для хранящихся данных (твой "iCash") - Varchar
data_type // Тип данных, хранящихся в строке 
data_value_int // Столбец для целочисленных данных
data_value_str // столбец для текста
data_value_float // Строка для вещественных данных
//И так для каждого типа, который ты будешь использовать впоследствии (добавлять будешь по мере необходимости 


---

Собственно, твои данные будут выглядеть в таблице так (для наглядности добавлю ещё пару строк с разными типами данных):

id	data_name	data_type	data_value_int	data_value_str	data_value_float
1	iCash	1	тут_значение_для_переменной	пустое_поле	пустое_поле
2	StringVariable_1	2	пустое_поле	тут_значение_для_переменной	пустое_поле
3	FloatVariable_1	3	пустое_поле	пустое_поле	тут_значение_для_переменной
4	StringVariable_2	2	пустое_поле	тут_значение_для_переменной	пустое_поле
5	StringVariable_3	2	пустое_поле	тут_значение_для_переменной	пустое_поле

И не нужно создавать миллион таблиц с миллионом столбцов и одной строкой, которая будет хранит все данные на свете.

 Готовый запрос на создание такой таблицы

PHP код:

---

CREATE TABLE `server_data` (
  `id` int(11) NOT NULL,
  `data_name` mediumtext NOT NULL,
  `data_type` int(11) NOT NULL,
  `data_value_int` int(11) NOT NULL,
  `data_value_str` mediumtext NOT NULL,
  `data_value_float` float NOT NULL
) ENGINE=InnoDB DEFAULT CHARSET=utf8;

ALTER TABLE `server_data`
  ADD PRIMARY KEY (`id`);

ALTER TABLE `server_data`
  MODIFY `id` int(11) NOT NULL AUTO_INCREMENT, AUTO_INCREMENT=1; 


---

Обработчик данных из таблицы будет выглядеть так:

  Открыть/закрыть

PHP код:

---

#define MAX_SDATA_NAME            17
#define MAX_DEFAULT_SDATA_LEN    11
enum
{
    SD_COLUMN_TYPE_INTEGER = 1, // Целое число
    SD_COLUMN_TYPE_STRING, // Строка
    SD_COLUMN_TYPE_FLOAT // Вещественное число
};

enum e_SERVER_DATA_INFO
{
    iCash,
    StringVariableOne[10],
    Float:FloatVariableOne,
    StringVariableTwo[15],
    StringVariableThree[144]
};
new ServerData[e_SERVER_DATA_INFO];
#define MAX_SERVER_DATA_STR_LEN 144

enum e_SD_DATABASE_INFO
{
    sdDataName[MAX_SDATA_NAME],
    sdDataType,
    e_SERVER_DATA_INFO:sdDataVariable,
    sdDefaultValueInt,
    sdDefaultValueString[MAX_DEFAULT_SDATA_LEN],
    Float:sdDefaultValueFloat
};
new sdDataBaseInfo[][e_SD_DATABASE_INFO] =
{
    {"iCash",                 SD_COLUMN_TYPE_INTEGER,            iCash,                    1_000_000,        "",                    0.0},
    {"StringVariable_1",    SD_COLUMN_TYPE_STRING,            StringVariableOne,        0,                "\0",                0.0},
    {"FloatVariable_1",        SD_COLUMN_TYPE_FLOAT,            FloatVariableOne,        0,                "",                    12.133},
    {"StringVariable_2",    SD_COLUMN_TYPE_STRING,            StringVariableTwo,        0,                "ServerName",        0.0},
    {"StringVariable_3",    SD_COLUMN_TYPE_STRING,            StringVariableThree,    0,                "DeimoS",            0.0}
};



stock LoadingServerData()
{
    new Cache:result = mysql_query(mysql_connection_ID, "SELECT * FROM server_data", true);

#if defined cache_get_value_name
    new rows;
    cache_get_row_count(rows);
#elseif defined cache_get_field_content
    new rows = cache_get_row_count();
#endif

    if(rows > sizeof(sdDataBaseInfo))    
    {
        printf(">>> LoadingServerData ERROR [1]: Количество строк в таблице \"server_data\" (%d шт) не равно количеству переменные (%d шт) <<", rows, sizeof(sdDataBaseInfo));
    }
    else
    {
        new data_list[sizeof(sdDataBaseInfo)],
            data_numm,
            data_name[MAX_SDATA_NAME],
            data_type;
        for(new i, j; i < rows; i++)
        {
        #if defined cache_get_value_name
            cache_get_value_name(i, "data_name", data_name);
            cache_get_value_name_int(i, "data_type", data_type);    
        #elseif defined cache_get_field_content
            cache_get_field_content(i, "data_name", data_name);
            data_type = cache_get_field_content_int(i, "data_type");
        #endif

            for(j = 0; j < sizeof(sdDataBaseInfo); j++)
            {
                if(data_type != sdDataBaseInfo[j][sdDataType] || strcmp(sdDataBaseInfo[j][sdDataName], data_name))
                    continue;
                switch(data_type)
                {
                    case SD_COLUMN_TYPE_INTEGER:
                    {
                    #if defined cache_get_value_name
                        cache_get_value_name_int(i, "data_value_int", ServerData[sdDataBaseInfo[j][sdDataVariable]]);
                    #elseif defined cache_get_field_content
                        ServerData[sdDataBaseInfo[j][sdDataVariable]] = cache_get_field_content_int(i, "data_value_int");
                    #endif
                        data_list[j] = 1;
                        data_numm++;
                        goto _sd_end;
                    }
                    case SD_COLUMN_TYPE_STRING:
                    {
                    #if defined cache_get_value_name
                        cache_get_value_name(i, "data_value_str", ServerData[sdDataBaseInfo[j][sdDataVariable]]);
                    #elseif defined cache_get_field_content
                        cache_get_field_content(i, "data_value_str", ServerData[sdDataBaseInfo[j][sdDataVariable]]);
                    #endif
                        data_list[j] = 1;
                        data_numm++;
                        goto _sd_end;
                    }
                    case SD_COLUMN_TYPE_FLOAT:
                    {
                    #if defined cache_get_value_name
                        cache_get_value_name_float(i, "data_value_float", Float:ServerData[sdDataBaseInfo[j][sdDataVariable]]);
                    #elseif defined cache_get_field_content
                        ServerData[Float:sdDataBaseInfo[j][sdDataVariable]] = cache_get_field_content_float(i, "data_value_float");
                    #endif
                        data_list[j] = 1;
                        data_numm++;
                        goto _sd_end;
                    }
                }
            }
            _sd_end:
        }
        cache_delete(result);
        if(data_numm != sizeof(sdDataBaseInfo))
        {
            new query_string[109+(11*4)+MAX_SDATA_NAME+MAX_DEFAULT_SDATA_LEN+1];
            for(new i; i < sizeof(sdDataBaseInfo); i++)
            {
                if(data_list[i] == 0)
                {
                    data_numm++;
                    format(query_string, sizeof(query_string), 
                        "\
                            INSERT INTO server_data(data_name,data_type,data_value_int,data_value_str,data_value_float) VALUES ('%s',%d,%d,'%s',%f)\
                        ", 
                            sdDataBaseInfo[i][sdDataName],
                            sdDataBaseInfo[i][sdDataType],
                            sdDataBaseInfo[i][sdDefaultValueInt],
                            sdDataBaseInfo[i][sdDefaultValueString],
                            sdDataBaseInfo[i][sdDefaultValueFloat]);
                    mysql_query(mysql_connection_ID, query_string, false);

                    switch(sdDataBaseInfo[i][sdDataType])
                    {
                        case SD_COLUMN_TYPE_INTEGER:
                        {
                            ServerData[sdDataBaseInfo[i][sdDataVariable]] = sdDataBaseInfo[i][sdDefaultValueInt];
                        }
                        case SD_COLUMN_TYPE_STRING:
                        {
                            strcat(ServerData[sdDataBaseInfo[i][sdDataVariable]], sdDataBaseInfo[i][sdDefaultValueString], MAX_DEFAULT_SDATA_LEN);
                        }
                        case SD_COLUMN_TYPE_FLOAT:
                        {
                            ServerData[sdDataBaseInfo[i][sdDataVariable]] = _:sdDataBaseInfo[i][sdDefaultValueFloat];
                        }
                    }
                }
            }
            if(data_numm > sizeof(sdDataBaseInfo))
            {
                printf(">>> LoadingServerData ERROR [2]: Количество строк в таблице \"server_data\" (%d шт) не равно количеству переменные (%d шт) <<", rows, sizeof(sdDataBaseInfo));
            }
        }
    }
    return 1;
}

stock UpdateServerData(e_SERVER_DATA_INFO:data_var)
{
    for(new i; i < sizeof(sdDataBaseInfo); i++)
    {
        if(sdDataBaseInfo[i][sdDataVariable] != data_var)
            continue;
        new query_string[44+19+MAX_SERVER_DATA_STR_LEN+MAX_SDATA_NAME+1];
        switch(sdDataBaseInfo[i][sdDataType])
        {
            case SD_COLUMN_TYPE_INTEGER:
            {
                format(query_string, sizeof(query_string), "data_value_int = %i", ServerData[data_var]);
            }
            case SD_COLUMN_TYPE_STRING:
            {
                format(query_string, sizeof(query_string), "data_value_str = '%s'", ServerData[data_var]);//19+MAX_SERVER_DATA_STR_LEN
            }
            case SD_COLUMN_TYPE_FLOAT:
            {
                format(query_string, sizeof(query_string), "data_value_float = %f", ServerData[data_var]);
            }
        }
        format(query_string, sizeof(query_string), 
            "\
                UPDATE server_data SET %s WHERE data_name = '%s'\
            ", 
                query_string,
                sdDataBaseInfo[i][sdDataName]);//44
        mysql_query(mysql_connection_ID, query_string, false);
        return 1;
    }
    return 0;
} 


---

Данная система работает с основными типами данных: целое число, вещественное число и строка. Другие типы можно без проблем добавить вручную.
Чтоб всё работало как надо, очень важно правильно заполнить все данные

Вот тут:

PHP код:

---

#define MAX_SDATA_NAME            17 


---

Указывается максимальный размер поля, которое записано в первом столбце массива sdDataBaseInfo.
А вот тут:

PHP код:

---

#define MAX_DEFAULT_SDATA_LEN    11 


---

Указывается максимальный размер для строчного значения по умолчанию, что хранится так же в sdDataBaseInfo в предпоследнем столбце.
Соответственно, всякий раз, когда ты изменяешь название поля/значение по умолчанию, ты должен по новой рассчитать максимальный размер.


Добавление новых переменных производится сначала в enum e_SERVER_DATA_INFO, а после в sdDataBaseInfo заносится информация для работы с таблицей. От того, как ты заполнишь эти данные, будет зависеть работоспособность всего остального кода
Собственно, по работе с enum вопросов быть не должно, а вот sdDataBaseInfo давай рассмотрим подробнее:

PHP код:

---

new sdDataBaseInfo[][e_SD_DATABASE_INFO] =
{
    {"iCash",                 SD_COLUMN_TYPE_INTEGER,            iCash,                    1_000_000,        "",                    0.0}
}; 


---

Первый столбец хранит в себе имя, под которым информация из переменной будет хранится в базе данных.
Второй столбец хранит тип переменной (целое число/строка/вещественное число). Очень важно правильно заполнить эту переменную, ибо от неё зависит то, как система будет обрабатывать данные (если указать неправильный тип, работать ничего не будет)
Третий столбец хранит в себе название переменной из enum e_SERVER_DATA_INFO
Четвёртый, пятый и шестой столбцы хранят в себе значение по умолчанию, которое будет задано строке в случае, если она не создана (то бишь, когда ты добавишь переменную и впервые запустишь сервер, запись в таблице для этой переменной будет создана автоматически и изначальное значение для строки и переменной будет взято именно отсюда). Отличие, соответственно, идёт по типу данных: "целое число | строка | вещественное число".

Собственно, всё. Больше ничего не требуется. Для обновления данных при их изменении делаешь следующее:

PHP код:

---

ServerData[iCash] = 666;
UpdateServerData(iCash); 


---

То бишь, сначала обновляешь данные в переменной, а потом вызываешь функцию UpdateServerData, указав в ней имя переменной из "enum e_SERVER_DATA_INFO"

- - - Добавлено - - -

Единственное: когда удаляешь переменную, нужно вручную удалять и данные из базы данных, иначе загрузка работать не будет (можно, конечно, реализовать автоудаление, но тогда в случае, если случайно удалишь не ту строку из массива sdDataBaseInfo, потеряешь данные и из таблицы. Лучше уж вручную контролировать этот процесс).
В остальном система самодостаточна и позволяет "на лету" создавать данные для хранения без каких-либо ковыряний в таблице.

Cпасибо но сложно тут больше написано чем в регистрации, я задам сразу прямо что хочу сделать
Например ты в регистрации делал 3 штукенции
id,name,password, я её у себя дальше дополнял типа там деньгами лвл и т.д

Мне надо по его типу то что ты написал. Если я задам сразу за них имена как это должно получиться

Я не бизнес типа же создаю мне нужна всего 1 строка под эти переменные
icash | imoney | ieuro | - вот это всё что нужно и снизу должна быть строка одна
0 | 0 | 0

И всё вот эти нули я буду заполнять уже с игры и т.д Мне нужно место хранение скажем так вот и всё что бы с ним взаимодействовать. Я думаю к этому код поменьше и по другому надо? Я не буду потом другие таблицы создавать мне лишь одно место хранение нужно и всё.

То что ты написал это аш отдельный урок нужно делать :D мне надо всего лишь целые числа хранить в одной строчке вот и всё. Для неё же меньше можно писать вообще другое ненужно лишь целые числа хранить нужно и всё. А там где icash это типа как id регистрации использовать но тут по другому типа крч.. я весь день мозги забивал. Можешь под эти переменные по типу аккаунтов подогнать код? Очень буду благодарен

Опять ничего не понял...
Тебе нужно просто хранить данные игрока или что?

Смотри мне не надо вообще хранить данные игрока.

Смотри есть люди.. у них есть дома машины. А есть банк. Банк одинокий и свободный она ни чья. Она просто стоит и хранит в себе деньги.

Люди подходят к одинокому банку и кидают ему деньги и банк заполняется. (icash | imoney | ieuro) | %d %d | %d

Есть люди которые подходят к банку и забирают оттуда деньги (icash | imoney | ieuro) | %d | %d| %d

Банк сам по себе. Банк никому не принадлежит. Банк это просто ячейка где хранятся деньги которые дали люди. Люди их могут оттуда забирать или положить.

Ну так у людей есть свой счёт в банке, который привязан к ним, не? Люди же не смогут забрать чужие деньги? Правильно, не смогут.
Так просто возьми и дополни таблицу аккаунтов столбцом с информацией о банковском счёте и всё. Так же, как и с обычными деньгами

SELECT - Нужно что бы при включении сервера подключалось к этой таблице.
Update - что бы обновлять данные в этой таблице с деньгами (когда игрок подойдет положит деньги и т.д или возьмет)
INSERT - Вот она будет нужна для создание одной строки. Что бы потом при каждом включении сервера она не создавала каждый раз.

Один раз запишет строку и потом уже должна проверять по типу аккаунтов. Мол "Строка с хранением денег есть, и создавать я её конечно же не буду"

Если строка не обнаружена, то он её создаст.

(НУЖНА лишь 1 строка и всё)

- - - Updated - - -

Никакого банка нет на сервере :D это пример. Мне нужно просто создать ячейку где будут храниться целые числа.
Нужна одна строка.
Таблица должна быть отдельной. Она аккаунтов игроков не будет касаться.
Таблица сама по себе живет при создании строки и всё. Она не будет дополняться другими строками.

Представь что это таблица - Автомат с едой. Она хранит в себе еду. Она ничья. Люди просто подходят и берут еду. Либо заполняют её едой.
Представь что это таблица - Общак. Она хранит в себе деньги. Она ничья. Люди просто подходят и берут деньги. Либо заполняют её деньгами.

Так возьми мою систему и всё. Какие проблемы?
Я повторяю: какой смысл держать целую таблицу ради пары столбцов и одной строки в ней? Что за извращение такое? Ты и эскалатор будешь строить ради лестницы, состоящей из трех ступеней?
Уж лучше тогда в файлы записывай или возьми написанную выше систему и используй её. Она делает ровно то, что хочешь ты, только подразумевает адекватное использование возможностей MySQL и удобное добавление новых строк в случае нужды

А как это на mxini сделать? Кстати нормальная идея :D Мне как раз и надо


DeimoS UPD: facepalm... Я умываю руки.

Создай то что ты мне отписал как отдельный урок, думаю я её учить буду как только перейду к глобальным системам в моде, мне пока что нужно просто хранить деньги на самом сервере и взаимодействовать с ним смогут другие игроки вот и всё.
Просто все кругом кричат "mysql кручи mxini" они мне забили голову. И я уже вот такой извращенец.

- - - Updated - - -

DeimoS спасибо :*) я бы в*ал плюс за твою помощь. но в*бу спасибо)

Цитата:

---

Сообщение от phpadmin

Создай то что ты мне отписал как отдельный урок, думаю я её учить буду как только перейду к глобальным системам в моде, мне пока что нужно просто хранить деньги на самом сервере и взаимодействовать с ним смогут другие игроки вот и всё.

---

В отдельном уроке нет смысла, ибо нечего объяснять. Там всё просто: нужно лишь сесть, попробовать добавить/убрать пару переменных и посмотреть на результат.
Моя система прекрасно подойдёт для того, что хочешь сделать ты. А ты лишь обрекаешь себя на переписывание кода в дальнейшем, если всё же захочешь сделать правильно и удобно.