Пробелы между цифрами

Вид для печати

17.08.2019, 00:45
scory

Пробелы между цифрами

Здравствуйте.
Как добавить пробелы между числами как на скринах? https://imgur.com/a/

stock AddDelimiterToInt(number, delimiter[2] = ".")
{
    new int_string[14+1];
    format(int_string, sizeof(int_string), "%d", number >= 0 ? number : -number);
    new value = strlen(int_string);
    switch(value)
    {
        case 4..6:
        {
            strins(int_string, delimiter, value-3,1);
        }
        case 7..9: 
        {
            strins(int_string, delimiter, value-3,1);
            strins(int_string, delimiter, value-6,1);
        }
        case 10..12: 
        {
            strins(int_string, delimiter, value-3,1);
            strins(int_string, delimiter, value-6,1);
            strins(int_string, delimiter, value-9,1);
        }
    }  
    if(number < 0) strins(int_string, "-", 0); 
    return int_string;
}

Использование:

new string[20+14+1];
format(string, sizeof(string), "Продаётся за $%s: /buy", AddDelimiterToInt(3000000, " "));
SendClientMessage(playerid, 0x0000FFFF, string);

Ещё вариант, с поддержкой Float и других тегов.

/*
    FormatNumber by Slice.
    -------------------------
    Usage:
        FormatNumber( number, decimals, thousand seperator, decimal point )
 
        number - This can be any variable type (float, integer, bool, etc.)
            If you want the value to be printed as HEX, tag the variable with hex. Example:
                new myvariable = 5312851;
 
                FormatNumber( hex:myvariable ); // gives 0x00511153
 
                Additionaly, you can print out the bits of either the first byte or the whole cell by using the following tags: bit:, bit_byte:
 
            If you get a type error, tag the variable with _. Example:
                new omgomg:specialVariable = omgomg:5;
 
                FormatNumber( _:specialVariable ); // gives 5
 
        decimals - The number of decimals to show
            new mynumber = 50;
 
            FormatNumber( mynumber, 2 ); // gives 50.00
 
            new Float:myfloat = 123.456;
 
            FormatNumber( myfloat, 0 ); // gives 123
 
        thousand seperator - char between thousands
            new mynumber = 5000000000;
 
            FormatNumber( myfloat ); // gives 5 000 000 000
            FormatNumber( myfloat, 0, ',' ); // gives 5,000,000,000
            FormatNumber( myfloat, 0, 0 ); // gives 5000000000
 
        decimal point - duh
            new myfloat = 50.0;
 
            FormatNumber( myfloat, 2, ' ', ',' ); // gives 50,00
            FormatNumber( myfloat, 2, ' ', '~' ); // gives 50~00
 
        You can set these constants __before__ including this file:
 
        HEX_PREFIX - default value "0x". Example:
            #define HEX_PREFIX "#"
 
            #include <formatnumber.inc>
 
            FormatNumber( hex:50000 ); // gives #0000C350
 
        BIT_PREFIX - default value: "0b"
 
        DEFAULT_DECIMAL_COUNT - default value: 8
 
        DEFAULT_THOUSAND_SEP - default value: ' '
 
        DEFAULT_DECIMAL_POINT - default value: '.'
*/
 
#if defined _formatnumber_included
    #endinput
#else
    #define _formatnumber_included
#endif
 
#if !defined HEX_PREFIX
    #define HEX_PREFIX  "0x"
#endif
 
#if !defined BIT_PREFIX
    #define BIT_PREFIX  "0b"
#endif
 
#if !defined DEFAULT_DECIMAL_COUNT
    #define DEFAULT_DECIMAL_COUNT  8
#endif
 
#if !defined DEFAULT_THOUSAND_SEP
    #define DEFAULT_THOUSAND_SEP  ' '
#endif
 
#if !defined DEFAULT_DECIMAL_POINT
    #define DEFAULT_DECIMAL_POINT  '.'
#endif
 
stock FormatNumber( { _, Float, Text3D, Menu, Text, DB, DBResult, bool, File, hex, Hex, bit, bit_byte, Bit }:xVariable, iDecimals = -1, iThousandSeparator = DEFAULT_THOUSAND_SEP, iDecimalPoint = DEFAULT_DECIMAL_POINT, iTag = tagof( xVariable ) )
{
    static
        s_szReturn[ 32 ],
        s_szThousandSeparator[ 2 ] = { ' ', EOS },
        s_iDecimalPos,
        s_iChar,
        s_iSepPos,
        bool:s_isNegative
    ;
 
    if ( iTag == tagof( bool: ) )
    {
        if ( xVariable )
            memcpy( s_szReturn, "true", 0, 5 * ( cellbits / 8 ) );
        else
            memcpy( s_szReturn, "false", 0, 6 * ( cellbits / 8 ) );
 
        return s_szReturn;
    }
    else if ( iTag == tagof( Float: ) )
    {
        if ( iDecimals == -1 )
            iDecimals = DEFAULT_DECIMAL_COUNT;
 
        format( s_szReturn, sizeof( s_szReturn ), "%.*f", iDecimals, xVariable );
 
        s_iDecimalPos = strfind( s_szReturn, "." );
    }
    else if ( iTag == tagof( hex: ) || iTag == tagof( Hex: ) )
    {
        format( s_szReturn, sizeof( s_szReturn ), HEX_PREFIX "%04h%04h", ( xVariable & ( 0xFFFF0000 ) ) >>> 16, xVariable & ( 0x0000FFFF ) );
 
        return s_szReturn;
    }
    else if ( iTag == tagof( bit: ) || iTag == tagof( Bit: ) )
    {
        format( s_szReturn, sizeof( s_szReturn ), BIT_PREFIX "%08b%08b%08b%08b", ( xVariable & 0xFF000000 ) >>> 24, ( xVariable & 0x00FF0000 ) >>> 16, ( xVariable & 0x0000FF00 ) >>> 8, ( xVariable & 0x000000FF ) );
 
        return s_szReturn;
    }
    else if ( iTag == tagof( bit_byte: ) )
    {
        format( s_szReturn, sizeof( s_szReturn ), BIT_PREFIX "%08b", ( xVariable & 0x000000FF ) );
 
        return s_szReturn;
    }
    else
    {
        format( s_szReturn, sizeof( s_szReturn ), "%d", xVariable );
        if ( iDecimals > 0 )
        {
            strcat( s_szReturn, "." );
 
            while ( iDecimals-- )
                strcat( s_szReturn, "0" );
        }
        s_iDecimalPos = -1;
    }
 
    if ( s_iDecimalPos == -1 )
        s_iDecimalPos = strlen( s_szReturn );
    else
        s_szReturn[ s_iDecimalPos ] = iDecimalPoint;
 
    if ( s_iDecimalPos >= 4 && iThousandSeparator )
    {
        s_szThousandSeparator[ 0 ] = iThousandSeparator;
 
        s_iChar = s_iDecimalPos;
        s_iSepPos = 0;
        s_isNegative = s_szReturn[0] == '-';
 
        while ( --s_iChar > _:s_isNegative )
        {
            if ( ++s_iSepPos == 3 )
            {
                strins( s_szReturn, s_szThousandSeparator, s_iChar );
 
                s_iSepPos = 0;
            }
        }
    }
    return s_szReturn;
}

Сделал свою версию

stock AddDelimiterToInt(value, const space[] = " ")
{
    new
        string[16],
        i,
        k,
        v = 3,
        s;
 
    format(string, sizeof string, "%i", value >= 0 ? value : -value);
 
    k = strlen(string);
    i = k/3;
    k %= 3;
 
    if (k != 0)
    {
        strins(string, space, k);
        k++;
    }
 
    while (--i > 0)
    {
        k += v;
        strins(string, space, k);
        v++;
    }
 
    if (value < 0)
        strins(string, "-", 0);
 
    return string;
}

Цитата:

Сообщение от m1n1vv

Сделал свою версию

stock AddDelimiterToInt(value, const space[] = " ")
{
    new
        string[16],
        i,
        k,
        v = 3,
        s;
 
    valstr(string, value >= 0 ? value : -value);
 
    k = strlen(string);
    i = k/3;
    k %= 3;
 
    if (k != 0)
    {
        strins(string, space, k);
        k++;
    }
 
    while (--i > 0)
    {
        k += v;
        strins(string, space, k);
        v++;
    }
 
    if (value < 0)
        strins(string, "-", 0);
 
    return string;
}

Реализация у Slice лучше. В твоем же коде могут быть ошибки при определенных ситуациях (например, OOB).

28.08.2019, 18:56
m1n1vv

Цитата:

Сообщение от vvw

Реализация у Slice лучше. В твоем же коде могут быть ошибки при определенных ситуациях (например, OOB).

Приведи пример
29.08.2019, 07:58
Daniel_Cortez
Цитата:
Сообщение от DeimoS

format(int_string, sizeof(int_string), "%d", number >= 0 ? number : -number);
Если параметр number имеет минимально возможное значение cellmin (-2147483648), то выражение (-number) выдаст 0. Да, так работает целочисленная арифметика: у минимального отрицательного значения нет положительного аналога, и нужно всегда иметь это в виду! Собственно, по той же причине и format() не может вывести это значение правильно, выдавая "--".
Цитата:
Сообщение от DeimoS

switch (value)
{
// ...
case 10..12:
Вот здесь не совсем понятно: для чего нужно именно "10..12", если положительное число в десятичной записи не может занимать больше 10 знаков?

Цитата:

Сообщение от vvw

Реализация у Slice лучше. В твоем же коде могут быть ошибки при определенных ситуациях (например, OOB).

Цитата:

Сообщение от m1n1vv

Приведи пример

За примерами далеко ходить не нужно (см. примечания по багам), можно добиться и записи за пределы массива, и зависания "намертво".

Вообще, ИМХО, вариант DeimoS'а выглядит почти идеальным, не считая перестановки всех элементов массива при вставке "-" (наверняка можно реализовать это как-то получше) и ещё пары уже упомянутых нюансов. Также настораживает в том варианте повторяющийся код внутри switch, но это такая особенность Pawn, что нельзя сделать, чтобы из одного case нельзя было "провалиться" в следующий, как в C/C++. Впрочем, это не ещё значит, что такую возможность нельзя добавить в компилятор :)
29.08.2019, 08:14
m1n1vv

Цитата:

Сообщение от Daniel_Cortez

За примерами далеко ходить не нужно (см. примечания по багам), можно добиться и записи за пределы массива, и зависания "намертво".

Не обращал на это внимание. Учту.
29.08.2019, 10:46
DeimoS
Цитата:

Сообщение от Daniel_Cortez

Если параметр number имеет минимально возможное значение cellmin (-2147483648), то выражение (-number) выдаст 0. Да, так работает целочисленная арифметика: у минимального отрицательного значения нет положительного аналога, и нужно всегда иметь это в виду! Собственно, по той же причине и format() не может вывести это значение правильно, выдавая "--".

Да, точно. Если честно, уже давно не вчитывался в код, который я там понаписал. Помнил просто, что, вроде как, всё работало и этот вариант быстрее варианта с циклом, поэтому и не парился. Мой косяк :D

Цитата:

Сообщение от Daniel_Cortez

Вот здесь не совсем понятно: для чего нужно именно "10..12", если положительное число в десятичной записи не может занимать больше 10 знаков?

Эту функцию я на pastebin выкладывал ещё году в 2015-ом и, если честно, не совсем помню какой логикой я руководствовался при написании этого кода :scratch_one-s_head:

В общем, как-то так:
Открыть/закрыть
stock AddDelimiterToInt(number, const delimiter[2] = ".")
{
new int_string[14+1];
if(number == cellmin)
int_string = "2147483648";
else
format(int_string, sizeof(int_string), "%d", number >= 0 ? number : -number);

new value = strlen(int_string);
switch(value)
{
case 4..6:
{
strins(int_string, delimiter, value-3,1);
}
case 7..9:
{
strins(int_string, delimiter, value-3,1);
strins(int_string, delimiter, value-6,1);
}
case 10:
{
strins(int_string, delimiter, value-3,1);
strins(int_string, delimiter, value-6,1);
strins(int_string, delimiter, value-9,1);
}
}
if(number < 0) strins(int_string, "-", 0);
return int_string;
}
Цитата:

Сообщение от Daniel_Cortez

не считая перестановки всех элементов массива при вставке "-" (наверняка можно реализовать это как-то получше)

Если ты про
format(int_string, sizeof(int_string), "%d", number >= 0 ? number : -number);
//...
if(number < 0) strins(int_string, "-", 0);
Тут я ничего лучше пока придумать не могу. При добавлении разделителя минус всё равно нужно учитывать, чтоб функция не добавила разделитель прямо после минуса в числах, а-ля "-100" или "-100000".
29.08.2019, 19:37
Геннадий Литвинов

А точки или запятые можно ли так поставить

Цитата:

Сообщение от m1n1vv

Не обращал на это внимание. Учту.

Справедливости ради, стоит также отметить, что и функция strins игнорирует передаваемый ей размер массива и может записать лишние символы за его пределы. Наверное, именно это vvw и имел в виду изначально.

Цитата:

Сообщение от Геннадий Литвинов

А точки или запятые можно ли так поставить

Да, для этого в приведённых в этой теме функциях есть параметр delimiter.

Немного поэкспериментировал и, кажется, нашёл оптимальный вариант реализации функции:
stock bool:FormatIntWithDelimiters(value, outstr[], delimiter = '.', size = sizeof(outstr))
{
    static delimiter_string[2] = { '\0', '\0' };
    static len;
    delimiter_string[0] = delimiter;
    if (value != cellmin)
        format(outstr, size, "%d", value);
    else
        outstr[0] = '\0', strcat(outstr, "-2147483648", size);
    len = strlen(outstr);
    switch (len - _:(value < 0))
    {
        case 10:
        {
            if (len + 3 >= size)
                return false;
            strins(outstr, delimiter_string, len - 3, 1);
            strins(outstr, delimiter_string, len - 6, 1);
            strins(outstr, delimiter_string, len - 9, 1);
        }
        case 7..9:
        {
            if (len + 2 >= size)
                return false;
            strins(outstr, delimiter_string, len - 3, 1);
            strins(outstr, delimiter_string, len - 6, 1);
        }
        case 4..6:
        {
            if (len + 1 >= size)
                return false;
            strins(outstr, delimiter_string, len - 3, 1);
        }
    }
    return true;
}
Отличается от других представленных в этой теме вариантов тем, что не подвержена багу с возвратом строки (сформатированная строка возвращается косвенно) и не производит лишних манипуляций с отдельной вставкой знака "-" и возвратом строки через стек.

29.08.2019, 21:43
vvw

Цитата:

Сообщение от m1n1vv

Приведи пример

Только сейчас заметил, что space, он же delimiter, имеет неявный размер, что также может привести к ошибке OOB.

- - - Добавлено - - -

Цитата:

Сообщение от Daniel_Cortez

Вообще, ИМХО, вариант DeimoS'а выглядит почти идеальным, не считая перестановки всех элементов массива при вставке "-" (наверняка можно реализовать это как-то получше) и ещё пары уже упомянутых нюансов. Также настораживает в том варианте повторяющийся код внутри switch, но это такая особенность Pawn, что нельзя сделать, чтобы из одного case нельзя было "провалиться" в следующий, как в C/C++. Впрочем, это не ещё значит, что такую возможность нельзя добавить в компилятор :)

В последнее время очень много добавляют в компилятор. Это, с одной стороны, хорошо, а с другой стороны - уже другой язык без документации. Хотя сделать fallthrough (__fallthrough) нужно.
02.09.2019, 15:33
tnc

Если подключен Pawn.Regex, то можно паттерном это решить (это просто альтернативное решение)

Вставлю и свои 5 копеек.

FormatNumber(number, prefix[] = "$")
{
    new value[15],
        length;
 
    format(value, sizeof(value), "%d", (number < 0) ? (-number) : (number));
 
    if ((length = strlen(value)) > 3)
    {
        for (new i = length, l = 0; --i >= 0; l ++) 
        {
            if ((l > 0) && (l % 3 == 0)) strins(value, ",", i + 1);
        }
    }
    if (prefix[0] != 0)
        strins(value, prefix, 0);
 
    if (number < 0)
        strins(value, "-", 0);
 
    return value;
}

Выглядит вот так:

Открыть/закрыть

Если не работает скриншот под спойлером - Клик-клик-клик

Команда для теста (зависимость от sscanf, zcmd/DC_CMD/Pawn.CMD/izcmd и прочих обработчиков синтаксиса zcmd):

CMD:test(playerid, params[])
{
    new const fmt_str[] = "{FF9900}[debug]{F6F6F6}: %s";
    new arr_sizeof[sizeof fmt_str + (-2 + 15)];
 
    extract params -> new value; else
        return SendClientMessage(playerid, -1, "/test [value]");
 
    format(arr_sizeof, sizeof(arr_sizeof), fmt_str, FormatNumber(value));
    SendClientMessage(playerid, -1, arr_sizeof);
    return 1;
}

Цитата:
Сообщение от Kovshevoy
Вставлю и свои 5 копеек.
FormatNumber(number, prefix[] = "$")
{
    new value[15],
        length;
 
    format(value, sizeof(value), "%d", (number < 0) ? (-number) : (number));
 
    if ((length = strlen(value)) > 3)
    {
        for (new i = length, l = 0; --i >= 0; l ++) 
        {
            if ((l > 0) && (l % 3 == 0)) strins(value, ",", i + 1);
        }
    }
    if (prefix[0] != 0)
        strins(value, prefix, 0);
 
    if (number < 0)
        strins(value, "-", 0);
 
    return value;
}
Выглядит вот так:
Открыть/закрыть
http://prntscr.com/qavw8k

Если не работает скриншот под спойлером - Клик-клик-клик

Команда для теста (зависимость от sscanf, zcmd/DC_CMD/Pawn.CMD/izcmd и прочих обработчиков синтаксиса zcmd):
CMD:test(playerid, params[])
{
    new const fmt_str[] = "{FF9900}[debug]{F6F6F6}: %s";
    new arr_sizeof[sizeof fmt_str + (-2 + 15)];
 
    extract params -> new value; else
        return SendClientMessage(playerid, -1, "/test [value]");
 
    format(arr_sizeof, sizeof(arr_sizeof), fmt_str, FormatNumber(value));
    SendClientMessage(playerid, -1, arr_sizeof);
    return 1;
}
Эмм, и смысл перебирать каждый символ, при этом, тратя время на деление, если можно сразу узнать количество символов в числе и расставить разделители? Собственно, как в моём варианте функции сделано.

Цитата:

Сообщение от Daniel_Cortez

Справедливости ради, стоит также отметить, что и функция strins игнорирует передаваемый ей размер массива и может записать лишние символы за его пределы. Наверное, именно это vvw и имел в виду изначально.

Да, для этого в приведённых в этой теме функциях есть параметр delimiter.

Немного поэкспериментировал и, кажется, нашёл оптимальный вариант реализации функции:

stock bool:FormatIntWithDelimiters(value, outstr[], delimiter = '.', size = sizeof(outstr))
{
    static delimiter_string[2] = { '\0', '\0' };
    static len;
    delimiter_string[0] = delimiter;
    if (value != cellmin)
        format(outstr, size, "%d", value);
    else
        outstr[0] = '\0', strcat(outstr, "-2147483648", size);
    len = strlen(outstr);
    switch (len - _:(value < 0))
    {
        case 10:
        {
            if (len + 3 >= size)
                return false;
            strins(outstr, delimiter_string, len - 3, 1);
            strins(outstr, delimiter_string, len - 6, 1);
            strins(outstr, delimiter_string, len - 9, 1);
        }
        case 7..9:
        {
            if (len + 2 >= size)
                return false;
            strins(outstr, delimiter_string, len - 3, 1);
            strins(outstr, delimiter_string, len - 6, 1);
        }
        case 4..6:
        {
            if (len + 1 >= size)
                return false;
            strins(outstr, delimiter_string, len - 3, 1);
        }
    }
    return true;
}

Отличается от других представленных в этой теме вариантов тем, что не подвержена багу с возвратом строки (сформатированная строка возвращается косвенно) и не производит лишних манипуляций с отдельной вставкой знака "-" и возвратом строки через стек.

С fixes вызывает выходы за пределы массива. (Не знаю почему, не было времени разобраться. Скорее всего что-то связанное с фиксом размера maxlength, но я не уверен. Нужно дебагать). Банальный фикс выглядит примерно так:

#include <a_samp>
#include <fixes>
 
forward bool:FormatIntWithDelimiters(value, outstr[], delimiter = '.', size = sizeof(outstr));
 
main()
{
    static const nums[] = 
    {
        500,
        1_000,
        10_000,
        100_000,
        1_000_000,
        cellmax
    };
 
    new str_num[64];
 
    for (new i = 0; i < sizeof(nums); i++)
    {
        FormatIntWithDelimiters(nums[i], str_num);
        printf("str_num: %s", str_num);
        str_num[0] = '\0';
    }
}
 
stock bool:FormatIntWithDelimiters(value, outstr[], delimiter = '.', size = sizeof(outstr))
{
    static delimiter_string[2] = { '\0', '\0' };
    static len;
    delimiter_string[0] = delimiter;
    if (value != cellmin)
        format(outstr, size, "%d", value);
    else
        outstr[0] = '\0', strcat(outstr, "-2147483648", size);
    len = strlen(outstr);
    switch (len - _:(value < 0))
    {
        case 10:
        {
            if (len + 3 >= size)
                return false;
 
            format(outstr, size, "%.*s%s%s", len - 3, outstr, delimiter_string, outstr[len - 3]);
            format(outstr, size, "%.*s%s%s", len - 6, outstr, delimiter_string, outstr[len - 6]);
            format(outstr, size, "%.*s%s%s", len - 9, outstr, delimiter_string, outstr[len - 9]);
        }
        case 7..9:
        {
            if (len + 2 >= size)
                return false;
 
            format(outstr, size, "%.*s%s%s", len - 3, outstr, delimiter_string, outstr[len - 3]);
            format(outstr, size, "%.*s%s%s", len - 6, outstr, delimiter_string, outstr[len - 6]);
        }
        case 4..6:
        {
            if (len + 1 >= size)
                return false;
 
            format(outstr, size, "%.*s%s%s", len - 3, outstr, delimiter_string, outstr[len - 3]);
        }
    }
    return true;
}

P.S: Не знаю насколько оправдан тут format, но мне нужен был быстрый фикс