не работает команда /time

помогите решить проблемму при вводе команды выходит непонятная ошибка

PHP код:

---

CMD:time(playerid, params[])
{
    if(PlayerLogged[playerid] == 0) return true;
    new mtext[20];
    new year, month,day;
    getdate(year, month, day);
    if(month == 1) { mtext = "January"; }
    else if(month == 2) { mtext = "February"; }
    else if(month == 3) { mtext = "March"; }
    else if(month == 4) { mtext = "April"; }
    else if(month == 5) { mtext = "May"; }
    else if(month == 6) { mtext = "June"; }
    else if(month == 7) { mtext = "Juli"; }
    else if(month == 8) { mtext = "August"; }
    else if(month == 9) { mtext = "September"; }
    else if(month == 10) { mtext = "October"; }
    else if(month == 11) { mtext = "November"; }
    else if(month == 12) { mtext = "December"; }
    new hour,minuite,second;
    gettime(hour,minuite,second);
    if (minuite < 10)
    {
        if (PlayerInfo[playerid][pMorganTime] > 0) format(totalstring, 128, "~y~%d %s~n~~g~|~w~%d:0%d~g~|~n~~w~Jail Time Left: %d sec", day, mtext, hour, minuite, PlayerInfo[playerid][pMorganTime]-10);
        else format(totalstring, 127, "~y~%d %s~n~~g~|~w~%d:0%d~g~|", day, mtext, hour, minuite);
    }
    else
    {
        if (PlayerInfo[playerid][pMorganTime] > 0) format(totalstring, 128, "~y~%d %s~n~~g~|~w~%d:%d~g~|~n~~w~Jail Time Left: %d sec", day, mtext, hour, minuite, PlayerInfo[playerid][pMorganTime]-10);
        else format(totalstring, 127, "~y~%d %s~n~~g~|~w~%d:%d~g~|", day, mtext, hour, minuite);
    }
    GameTextForPlayer(playerid, totalstring, 5000, 1);
    ApplyAnimation(playerid,"COP_AMBIENT","Coplook_watch",4.1,0,0,0,0,0,1);
    format(totalstring, 64, "%s взглянул(а) на часы", PlayerInfo[playerid][pSendername]);
    ProxDetectorNew(playerid,30.0,COLOR_PURPLE,totalstring);
    return true;
} 


---

PHP код:

---

CMD:time(playerid, params[]) 
{ 
    if (PlayerLogged[playerid] == 0)
        return true; 

    new
        string[64],
        year, month,day,
        hour,minuite,second; 

    static const
        str_month[][] =
        {
            "January",
            "February",
            "March",
            "April",
            "May",
            "June",
            "Juli",
            "August",
            "September",
            "October",
            "November",
            "December"
    };

    getdate(year, month, day); 
    gettime(hour,minuite,second); 

    format(string, sizeof string, "~y~%d %s~n~~g~|~w~%d:%01d", day, str_month[month-1], hour, minuite);
    if (PlayerInfo[playerid][pMorganTime] > 0)
        format(string, sizeof string, "%s~g~|~n~~w~Jail Time Left: %d sec", string, PlayerInfo[playerid][pMorganTime]-10); 

    GameTextForPlayer(playerid, string, 5000, 1); 
    ApplyAnimation(playerid,"COP_AMBIENT","Coplook_watch",4.1,0,0,0,0,0,1); 
    format(string, sizeof string, "%s взглянул(а) на часы", PlayerInfo[playerid][pSendername]); 
    ProxDetectorNew(playerid,30.0,COLOR_PURPLE,string); 

    return true; 
} 


---

Проверку на заключение сам добавишь, не так сложно, или же, если не по силам, то бери предложенный вариант выше.

Код:

---

CMD:time(playerid)
{
    if(GetPlayerState(playerid) == 1) {
                ApplyAnimation(playerid,"COP_AMBIENT","Coplook_watch",4.1,0,0,0,0,0);
        }
        new year,month,day,hour,minuite,second;
        static const
                chat[] = "%s взглянул(а) на часы";
        new
                str_chat[sizeof(chat)+(MAX_PLAYER_NAME-2)];
        format(
                str_chat,
                sizeof(str_chat),
                chat,
                Name(playerid));

        SetPlayerChatBubble(playerid,str_chat,COLOR_PURPLE,10.0,10000);
        getdate(year, month, day);
        gettime(hour, minuite, second);

        static const
                names_months[12][12] = {
                        "January","February","March","April","May","June","July","\
                        ""August","September","October","November","December"};

        static const
            datte[] = "%d %s~n~~w~%02d:%02d";
        new
                str_datte[sizeof(datte)+(2-2)+(2-2)+(2-2)+6];
        format(
                str_datte,
                sizeof(str_datte),
                datte,day,
                names_months[month-1],
                hour,
                minuite);

        GameTextForPlayer(playerid,str_datte,1000,1);
        return true;
}

---

верхний вариант работает также как и было
выдает ошибку [USAGE] /t HOUR or /time HOUR при вводе одной из этих команд выдает [CUCCESS] Time has changed to HOUR 0

Цитата:

---

Сообщение от Andrik851

верхний вариант работает также как и было
выдает ошибку [USAGE] /t HOUR or /time HOUR при вводе одной из этих команд выдает [CUCCESS] Time has changed to HOUR 0

---

В таком случае компилятор должен выдавать предупреждения, напиши их номера, а лучше просто скинь сюда.

Компилятор ничего не выдает все в норме да и часы я в магазине покупаю

У вас есть команда с таким же названием, которая имеет другое назначение. Вероятно в фильтрскрипте. Просто переименуйте одну из команд.