numargs?

Пока на уровне новичка осваиваю работу с аргументами и непонятно как лучше сделать рабочий вариант этой функции:

Код HTML:

---

stock TimeFunction(func[], interval, const format[] = "", ...){
        if(!strlen(format)) return SetTimer(func[], interval, false);
        else {

                new arg[numargs()];
                for(new i = 3, j = numargs(); i < j; i++) arg[i-3] = getarg(arg, i);
                return SetTimerEx(func[], interval, false, format[], arg);

        }
}

---

Как-то так (va_SetTimerEx взята из библиотеки YSI).

Ибо иначе передать аргументы в SetTimerEx ты никак не сможешь.

stock va_SetTimerEx(const function[], interval, bool:repeating, const fmat[], STATIC_ARGS)
{
    static
        sRet;
    new
        num_args,
        arg_start,
        arg_end;
    // Get the pointer to the number of arguments to the last function.
    #emit LOAD.S.pri   0
    #emit ADD.C        8
    #emit MOVE.alt
    // Get the number of arguments.
    #emit LOAD.I
    #emit STOR.S.pri   num_args
    // Get the variable arguments (end).
    #emit ADD
    #emit STOR.S.pri   arg_end
    // Get the variable arguments (start).
    #emit LOAD.S.pri   STATIC_ARGS
    #emit SMUL.C       4
    #emit ADD
    #emit STOR.S.pri   arg_start
    // Using an assembly loop here screwed the code up as the labels added some
    // odd stack/frame manipulation code...
    while (arg_end != arg_start)
    {
        #emit MOVE.pri
        #emit LOAD.I
        #emit PUSH.pri
        #emit CONST.pri    4
        #emit SUB.alt
        #emit STOR.S.pri   arg_end
    }
    // Push the additional parameters.
    #emit PUSH.S       fmat
    #emit PUSH.S       repeating
    #emit PUSH.S       interval
    #emit PUSH.S       function
    // Push the argument count.
    #emit LOAD.S.pri   num_args
    #emit ADD.C        16
    #emit LOAD.S.alt   STATIC_ARGS
    #emit XCHG
    #emit SMUL.C       4
    #emit SUB.alt
    #emit PUSH.pri
    #emit MOVE.alt
    // This gets confused if you have a local variable of the same name as it
    // seems to factor in them first, so you get the offset of the local
    // variable instead of the index of the native.
    #emit SYSREQ.C     SetTimerEx
    #emit STOR.pri     sRet
    // Clear the stack.
    #emit CONST.pri    4
    #emit ADD
    #emit MOVE.alt
    // The three lines above get the total stack data size, now remove it.
    #emit LCTRL        4
    #emit ADD
    #emit SCTRL        4
    // Now do the real return.
    return sRet;
}
 
stock TimeFunction(const func[], interval, const format[] = "", ...){
 
    new
        args = numargs();
 
    const ARGS_START = 3;
 
    if (args > ARGS_START)
    {
        va_SetTimerEx(func, interval, false, format, ARGS_START);
    }
    else
    {
        SetTimer(func, interval, false);
    }
}

О Господи, за что. А getarg ну никак?

Цитата:

---

Сообщение от MassonNN

О Господи, за что. А getarg ну никак?

---

Можно и через getarg, но эта реализация будет максимально медленной относительно варианта на emit.

Ну и да: ничего не хочу сказать, но твой код функционально эквивалентен

SetTimerEx("SomeFunc", 1000, true, "");

Можно ещё сделать так:

native TimerFunction(funcname[], interval, repeating, const format[] = "", {Float,_}:...) = SetTimerEx;

И тогда использование будет выглядеть так:

TimerFunction("SomeFunc", 1000, true);

Хотя, имхо, это какой-то говнокодинг.

делаю эту функцию, чтобы другие функции можно было вызывать, в том числе нативные