/id с темы по sscanf'у.

[Тузик]

Решил почитать документацию по sscanf'у, но немного не понял часть с получением полу-игрового имени. (MATCH_NAME_PARTIAL)

Можете подсказать как улучшить, да и в общем, правильно ли написал (правильно ли скопировал*)? На 1-ом игроке (мне) все отлично работает, не жалусь

CMD:id(playerid, params[])
{
    new targetid[10], nickname[MAX_PLAYER_NAME], i, string[MAX_PLAYER_NAME*10+7-6];
    if(sscanf(params, "?<MATCH_NAME_PARTIAL=1>u[10]", targetid)) SendClientMessage(playerid, 0xFFFFFFAA, "(( Используйте: /id <targetid / nickname> ))");

    while(targetid[i] != INVALID_PLAYER_ID)
    {
        if(targetid[i] == cellmin)
        {
            SendClientMessage(playerid, 0xFFFFFFAA, "(( Слишком много совпадений ))");
            break;
        }
        GetPlayerName(targetid[i], nickname, MAX_PLAYER_NAME);
        format(string, sizeof(string), "%s- %s [%d];\n", string, nickname, targetid[i]);
        ++i;
    }
    if(!i) return SendClientMessage(playerid, 0xFFFFFFAA, "(( Слишком мало данных для поиска ))");
    
    SendClientMessage(playerid, 0xFFFFFFAA, string);
    return 1;
}  

[Guldan]

Разве не так?

if(sscanf(params,"u", targetid))  

[ziggi]

Вроде нормально всё (разве что после срабатывания sscanf нужно выйти из функции), но я её улучшил (как мне кажется) подсветкой введённых символов в найденных никах:

insert_pos = strfind(string, params, true);
if (insert_pos != -1) {
    strins(string, "{FFFFFF}", strlen(params) + insert_pos);
    strins(string, "{FF8888}", insert_pos);
}  

Разве не так?

if(sscanf(params,"u", targetid))  

Это лишь для одного игрока.

[Guldan]

Ты хочешь \n использовать в SendClientMessage

- - - Добавлено - - -

CMD:id(playerid, params[]) 
{ 
    new targetid[10], nickname[MAX_PLAYER_NAME], i, string[MAX_PLAYER_NAME+10-4]; 
    if(sscanf(params, "?<MATCH_NAME_PARTIAL=1>u[10]", targetid)) SendClientMessage(playerid, 0xFFFFFFAA, "(( Используйте: /id <targetid / nickname> ))"); 
 
    while(targetid[i] != INVALID_PLAYER_ID) 
    { 
        if(targetid[i] == cellmin) 
        { 
            SendClientMessage(playerid, 0xFFFFFFAA, "(( Слишком много совпадений ))"); 
            break; 
        } 
        GetPlayerName(targetid[i], nickname, MAX_PLAYER_NAME); 
        format(string, sizeof(string), "- %s [%d];", nickname, targetid[i]); 
        SendClientMessage(playerid, 0xFFFFFFAA, string); 
        ++i; 
    } 
    if(!i) SendClientMessage(playerid, 0xFFFFFFAA, "(( Слишком мало данных для поиска ))"); 
    return 1; 
}  

[ziggi]

Ты хочешь \n использовать в SendClientMessage

И правда. Тогда я лучше выложу свой вариант команды, но с текстом автора:

CMD:id(playerid, params[])
{
    #if !defined COMMAND_ID_MAX_MATCHES
        #define COMMAND_ID_MAX_MATCHES 10
    #endif

    new
        ids[COMMAND_ID_MAX_MATCHES];

    if (sscanf(params, "?<MATCH_NAME_PARTIAL=1>u[" #COMMAND_ID_MAX_MATCHES "]", ids)) {
        SendClientMessage(playerid, 0xFFFFFFAA, "(( Используйте: /id <targetid / nickname> ))");
        return 1;
    }
    #undef COMMAND_ID_MAX_MATCHES

    new
        i,
        insert_pos,
        string[MAX_PLAYER_NAME + 16 + 4 + 3 + 1];

    while (ids[i] != INVALID_PLAYER_ID) {
        if (ids[i] == cellmin) {
            SendClientMessage(playerid, 0xFFFFFFAA, "(( Слишком много совпадений ))");
            break;
        }

        GetPlayerName(ids[i], string, sizeof(string));

        insert_pos = strfind(string, params, true);
        if (insert_pos != -1) {
            strins(string, "{FFFFFF}", strlen(params) + insert_pos);
            strins(string, "{FF8888}", insert_pos);
        }

        format(string, sizeof(string), "%s [%d];", string, ids[i]);
        SendClientMessage(playerid, 0xFFFFFFAA, string);

        ++i;
    }

    if (i == 0) {
        SendClientMessage(playerid, 0xFFFFFFAA, "(( Слишком мало данных для поиска ))");
    }
    return 1;
}  

[Тузик]

Да я спал, мозг еще не включил, спасибо за замечание)

[Guldan]

Для какой цели эта команда если не секрет?

- - - Добавлено - - -

Вариант ziggi:
У тебя string = 48
GetPlayerName(ids[i], string, sizeof(string));

Тогда лучше так:
GetPlayerName(ids[i], string, MAX_PLAYER_NAME);

[Тузик]

Поиск схожих с именем (может быть и идентификатором) игроков.

Например:
/id Tu

- Tuz
- Tuzyk
- Tuzykovich

:)

Кстати да, согласен с использованием константы. Так как подсчет кол-ва ячеек навряд ли в стандартном теле будет необходимо.

[ziggi]

Для какой цели эта команда если не секрет?

- - - Добавлено - - -

Вариант ziggi:
У тебя string = 48
GetPlayerName(ids[i], string, sizeof(string));

Тогда лучше так:
GetPlayerName(ids[i], string, MAX_PLAYER_NAME);

Согласен, поправил.

[Daniel_Cortez]

Тогда лучше так:
GetPlayerName(ids[i], string, MAX_PLAYER_NAME);

И чем это лучше? Тем, что обманываете GetPlayerName с размером string?

UPD: Макрос COMMAND_ID_MAX_MATCHES следует убрать (#undef) либо после выражения со sscanf, либо в конце функции, чтобы не было конфликтов при аналогичном использовании этого макроса в других функциях.