Обратный отсчет

[pustomerzha]

Как при помощи таймера сделать обратный отсчет времени? Прошу желательно ответить кодом

[qwezert]

Как при помощи таймера сделать обратный отсчет времени? Прошу желательно ответить кодом

new final_count_timer; 
new final_count = 10; // Задаем число отсчета 
//Можно создать для каждого игрока добавив [MAX_PLAYERS] и в дальнейшем используя [playerid] 
// new final_count_timer[MAX_PLAYERS]; 
// final_count_timer[playerid] = SetTimer("Revers", 1000, false); 
 
public OnGameModeInit() 
{ 
    print("Запуск таймера..."); 
    final_count_timer = SetTimer("Revers", 1000, false); // Устанавливает таймер на 1000 миллисекунд (1 секунда) 
} 
 
public Revers()//Сам каллбек таймера 
{ 
    if(final_count > 0) //Условие проверки переменной, что бы у нас счет не уходил в минус. 
    { 
        final_count--; //Отнимаем -1; 
        printf("Осталось %i секунд",final_count); 
    } 
    else 
    {  
        final_count = 10; 
        KillTimer(final_count_timer); //Убиваем таймер. 
    } 
}  

Это простенький пример. Думаю дальше ты сам сможешь понять что куда. Удачи)

[DeimoS]

...

Если ты хотел делать таймер с повторением, то забыл в SetTimer указать "true" =)

Можно так же обойтись и средствами одного таймера, передавая все нужные данные в качестве параметров (но я крайне сомневаюсь, что это вариант лучше того, что дал ты. Просто как пример использования SetTimerEx).

public OnGameModeInit() 
{ 
    print("Запуск таймера..."); 
    SetTimerEx("Revers", 1000, false, "d", 10); 
    /* 
        Устанавливает таймер на 1000 миллисекунд (1 секунда) 
        И указываем на то, сколько повторений совершит таймер
        (в "10" включается и последнее повторение, которое приведёт к вызову "print("Условие выполнено\n\n");"
          То есть, в консоли отсчёт начнётся с 9 и окончится на 1, а после произойдёт вызов кода, что я дал выше).
    */
} 

forward Revers(final_count);
public Revers(final_count)
{
    if(--final_count > 0)
    { 
        printf("Осталось %i секунд", final_count); 
        SetTimerEx("Revers", 1000, false, "d", final_count);
    } 
    else
    {
        print("Условие выполнено\n\n"); 
    }
    return 1;
}  

 То же самое, только для конкретного игрока

public OnPlayerConnect(playerid)
{
    print("Запуск таймера..."); 
    SetTimerEx("Revers", 1000, false, "dd", 10, playerid); 
    /* 
        Устанавливает таймер на 1000 миллисекунд (1 секунда) 
        Указываем то, сколько повторений совершит таймер и передаём ID для дальнейшей работы с игроком 
    */
    return 1;
}

forward Revers(final_count, playerid);
public Revers(final_count, playerid)
{
    if(!IsPlayerConnected(playerid))// Предотвратим вызов таймера в случае, если игрок отключился
        return 1;

    if(--final_count > 0)
    { 
        printf("[ID: %d] Осталось %i секунд", playerid, final_count); 
        SetTimerEx("Revers", 1000, false, "dd", final_count, playerid);
    } 
    else
    {
        printf("[ID: %d] Условие выполнено\n\n", playerid); 
    }
    return 1;
}  

Соответственно, так можно передавать не только ID, но и любую другую нужную информацию, а новый таймер будет априори "индивидуальным" (запустите 2 таймера и они оба будут работать со своими значениями).

[qwezert]

....

Да с false чет я лажанул :) Наши варианты впринципе одинаковые, тут уже кому как нравится, единственное что в моем варианте отсчет начнется с 10 а в твоем с 9.
Мне вот даже интересно стало, если таймер нужно запустить для определенного кол-ва игроков, то получается в сам каллбек нужно будет передать массив нужных игроков и через for прогонять и для каждого игрока отнимать 1?
Или можно как то проще сделать?

[DeimoS]

в моем варианте отсчет начнется с 10 а в твоем с 9.

10 поменяй на 11 и отсчёт начнётся с 10 :)

Мне вот даже интересно стало, если таймер нужно запустить для определенного кол-ва игроков, то получается в сам каллбек нужно будет передать массив нужных игроков и через for прогонять и для каждого игрока отнимать 1?
Или можно как то проще сделать?

Если для нескольких игроков один таймер, то используешь первый вариант и в нём цикл, в котором уже нужным игрокам и отображаешь информацию.
Если же для 10 игроков свой таймер (например, антифлуд), то второй вариант (каждому игроку свой таймер)

[qwezert]

Если для нескольких игроков один таймер, то используешь первый вариант и в нём цикл, в котором уже нужным игрокам и отображаешь информацию.
Если же для 10 игроков свой таймер (например, антифлуд), то второй вариант (каждому игроку свой таймер)

Ну я так и написал, думал можно как то по другому сделать)