/mute & /unmute в одной кмд (dc_cmd / zcmd) + sscanf

[L0ndl3m]

Команда действует по принципу: Если игрок заткнут, то его разоткнёт, и наоборот.

Ко всем new:

new
    p_muted[MAX_PLAYERS char]
;  

Теперь проверку - заткнут ли игрок:
В public OnPlayerText:

if(p_muted{playerid})
{
    SendClientMessage(playerid, -1, "Вы заткнуты.");
    return 0;
}  

Ко всем командам:

CMD:mute(playerid, params[])
{
    extract params -> new player: targetid; else
        return SendClientMessage(playerid, -1, "Используйте: /mute [ID игрока / часть ника]");
    if(IsPlayerConnected(targetid) == 0)
        return SendClientMessage(playerid, -1, "Такого игрока нет на сервере.");

    p_muted{targetid} = !p_muted{targetid};

    static const
        fmt_str[] = "%s (%d) %sткнул %s (%d)."
    ;

    new
        str[sizeof(fmt_str) - 2 + MAX_PLAYER_NAME - 2 + 3 - 2 + 4 - 2 + MAX_PLAYER_NAME - 2 + 3],
        targetname[MAX_PLAYER_NAME + 1]
    ;

    GetPlayerName(playerid, str, sizeof(str));
    GetPlayerName(targetid, targetname, sizeof(targetname));
    format(str, sizeof(str), fmt_str, str, playerid, p_muted{targetid} ? ("за") : ("разо"), targetname, targetid);
    return SendClientMessageToAll(-1, str);
}  

Автор: Londlem

Специально для: Pro-Pawn.Ru

Копирование данной статьи без разрешения автора запрещено!

[Osiris]

Как сделать чтобы можно было затыкать на минуты? (ZCMD)

[L0ndl3m]

Как сделать чтобы можно было затыкать на минуты? (ZCMD)

Команда:

CMD:mute(playerid, params[])
{
    if(sscanf(params, "ud", params[0], params[1]))
        SendClientMessage(playerid, -1, "Используйте: /mute [playerid] [minutes]");
    if(IsPlayerConnected(params[0]) == 0)
        return SendClientMessage(playerid, -1, "Такого игрока нет на сервере.");

    new
        server_tick = GetTickCount()
    ;

    if(GetPVarInt(params[0], "MuteTime") > server_tick)
        return SendClientMessage(playerid, -1, "Игрок уже заткнут.");

    SetPVarInt(params[0], "MuteTime", server_tick + params[1] * 60000);

    static const
        fmt_str[] = "%s (%d) заткнул %s (%d) на кол-во минут: %d."
    ;

    new
        str[sizeof(fmt_str) - 2 + MAX_PLAYER_NAME - 2 + 3 - 2 + MAX_PLAYER_NAME - 2 + 3 - 2 + 11],
        targetname[MAX_PLAYER_NAME + 1]
    ;

    GetPlayerName(playerid, str, sizeof(str));
    GetPlayerName(params[0], targetname, sizeof(targetname));
    format(str, sizeof(str), fmt_str, str, playerid, targetname, params[0], params[1]);
    return SendClientMessageToAll(-1, str);
}  

В public OnPlayerText:

if(GetPVarInt(playerid, "MuteTime") > GetTickCount())
{
    SendClientMessage(playerid, -1, "Вы заткнуты.");
    return 0;
}  

[Osiris]

Огромное спасибо ^_^
Завтра спасибо дам, т.к лимит)

[Andrei_Smile]

не доработано,при реконекте мут спадет а в целом не плохо.

[L0ndl3m]

не доработано,при реконекте мут спадет а в целом не плохо.

Сохранение аккаунтов не у всех одинаковое.

[Merlin]

Хорошо + сделай её в обычном процеси по 1 мин

[L0ndl3m]

Хорошо + сделай её в обычном процеси по 1 мин

if(strcmp(tmp, "/mute", true, 5) == 0)
{
    tmp = strtok(cmdtext, idx);

    if(strlen(tmp) == 0)
        return SendClientMessage(playerid, -1, "Используйте: /mute [playerid] [minutes]");

    new
        targetid = strval(tmp)
    ;

    if(IsPlayerConnected(targetid) == 0)
        return SendClientMessage(playerid, -1, "Такого игрока нет на сервере.");
    
    tmp = strtok(cmdtext, idx);

    new
        time = strval(tmp)
    ;

    if(strlen(tmp) == 0)
        return SendClientMessage(playerid, -1, "Используйте: /mute [playerid] [minutes]");

    new
        server_tick = GetTickCount()
    ;

    if(GetPVarInt(targetid, "MuteTime") > server_tick)
        return SendClientMessage(playerid, -1, "Игрок уже заткнут.");

    SetPVarInt(targetid, "MuteTime", server_tick + time * 60000);
    
    static const
        fmt_str[] = "%s (%d) заткнул %s (%d) на кол-во минут: %d."
    ;

    new
        str[sizeof(fmt_str) - 2 + MAX_PLAYER_NAME - 2 + 3 - 2 + MAX_PLAYER_NAME - 2 + 3 - 2 + 11],
        targetname[MAX_PLAYER_NAME + 1]
    ;

    GetPlayerName(playerid, str, sizeof(str));
    GetPlayerName(targetid, targetname, sizeof(targetname));
    format(str, sizeof(str), fmt_str, str, playerid, targetname, targetid, time);
    return SendClientMessageToAll(-1, str);
}